Lompat ke konten
Anda disini: M Jurnal » Rumus Excel » Rumus IF Excel Tunggal dan Bertingkat [Aturan + 7 Contoh]

Rumus IF Excel Tunggal dan Bertingkat [Aturan + 7 Contoh]

Cara menggunakan rumus if Tunggal Excel

Rumus IF Excel termasuk dalam kategori fungsi logika (logical function) pada excel. Cara paling mudah menggunakan rumus ini adalah gunakan logika mu. Hukum JIKAMAKA berhubungan erat dengan rumus IF ini.

Penting! Penulisan seluruh rumus pada excel menggunakan operator pemisah antara setiap pernyataan, dapat berupa tanda koma (,) atau titik koma (;). Sesuaikan operator pemisah yang Anda gunakan. Saya menggunakan tanda koma (,). Jika Anda belum yakin, silahkan Pahami Panduan Koma Menjadi Titik Excel

Dalam praktiknya, ada banyak sekali cara menggunakan Rumus / Fungsi IF Excel ini. Misalnya seperti Rumus IF Excel Tungal, Bertingkat bahkan menggabungkan Fungsi IF dengan Fungsi lainnya seperti AND, OR, VLOOKUP dll.

Pada Panduan ini, Anda akan mempelajari semua cara penggunaan Fungsi IF ini yang Saya rangkum dalam beberapa contoh berbeda. Harap pahami setiap tahap demi tahap untuk mendapatkan pemahaman yang sempurna.

Aturan Penulisan Rumus IF Excel

Jika Anda ingin menjadi Ahli dalam menggunakan Fungsi IF, maka Memahami Aturan Penulisan Rumus IF = WAJIB

Pada dasarnya, Rumus IF adalah sebuah fungsi pada Ms. Excel untuk melakukan pengecekan, membandingkan, lalu menentukan pilihan ketika suatu kondisi / syarat telah terpenuhi.

Fungsi IF excel ini berguna untuk  menguji suatu data berdasarkan kriteria dengan pilihan Benar (True) atau Salah (False).

Note: True: hasil jika kriteria terpenuhi. False: hasil jika kriteria tidak terpenuhi

Minimal rumus IF harus terdiri dari pernyataan logika JIKAMAKA. Kedua pernyataan tersebut harus tersedia. Selain itu, pernyataan logika alternative boleh Anda gunakan ataupun tidak (tergantung bagaimana data Anda).

Tulis Fungsi / Rumus IF:
=IF(Logical_test,[value_if_true],[value_if_false])

Terdapat 3 argument rumus IF yang artinya sebagai berikut:

  1. Logical Test, merupakan nilai / cell / pernyataan / rumus tertentu yang akan diuji (dalam hal ini adalah “JIKA”).
  2. Value IF True, merupakan hasil yang diberikan Excel jika logical test adalah benar (dalam hal ini adalah “MAKA 1″).
  3. Value IF False, merupakan hasil yang diberikan Excel jika logical test adalah salah (dalam hal ini adalah pernyataan logika alternative atau “MAKA 2” / pilihan ke dua)

Ke tiga argument tersebut (Logical_Test, Value_IF_true dan Value_IF_false) bisa berupa sebuah nilai (ketik manual) / cell / rumus tertentu, baik dalam sheet yang sama maupun berbeda. Artinya, Anda juga bisa menggabungkan Rumus IF dengan rumus-rumus lainnya.

Sedikit saran, pahami terlebih dahulu beberapa contoh menggunakan Rumus IF Tunggal berikut sebelum Anda menggunakan Rumus IF Bertingkat ataupun menggabungkan Rumus IF dengan rumus-rumus Excel lainnya.

Cara Menggunakan Rumus IF Tunggal

Pertama-tama Rumus IF Tunggal artinya adalah satu. Artinya, Anda akan menggunakan 1 buah Rumus IF tanpa menggabungkannya dengan rumus IF ke 2, 3 dan seterusnya.

sponsored-jd-sport

Rumus IF tunggal bisa Anda gunakan untuk menentukan 1 dari 2 persyaratan seperti contoh gambar berikut:

Contoh rumus if tunggal

Dalam contoh ini, Kita akan menentukan mata kuliah mana yang masuk dalam kategori LULUS. Perhatikan syarat yang Saya gunakan:

  • Nilai 70 sampai 100 adalah LULUS
  • Nilai kecil dari 70 adalah GAGAL

Berikut cara menggunakan rumus IF untuk melihat apakah nilai mata kuliah tersebut masuk dalam kategori lulus atau tidak.

  1. Klik Cell yang akan Menggunakan Fungsi IF. Dalam contoh ini cell C2.
    Cara menggunakan rumus if Excel
  2. Ketik =IF( pada formula bar untuk mengawali Fungsi IF.
    Cara menggunakan rumus if Excel
  3. Tentukan Argument logical_test (apa yang Anda uji / kriteria). Dalam contoh ini, kriteria pengujian ada 2 yaitu jika >= 70, maka LULUS dan jika <70, maka GAGAL. Silahkan masukkan kriteria pertama untuk logical_test. Caranya, Klik Cell yang akan diuji (B2), ketik >=70 , kemudian ketik Operator pemisah Rumus ( tanda koma , atau titik koma ; ) sehingga Rumus menjadi =IF(B2>=70,
    Cara menggunakan rumus if Excel
  4. Masukkan Argument value_if_true (hasil jika logical_test benar). Jadi jika Cell B2 berisi nilai >=70, maka hasil ini lah yang akan diberikan Excel. Silahkan ketik “LULUS” besarta tanda kutip 2 kemudian ketik operator pemisah rumus ( , atau ; ). Sehingga Rumus menjadi =IF(B2>=70,"LULUS",
    Cara menggunakan rumus if Excel
  5. Masukkan Argument value_if_false (hasil yang akan diberikan Excel jika logical_test tidak benar). Jadi, jika nilai pada Cell B2 tidak berisi >=70, maka Excel akan memberikan hasil sesuai value_if_false ini. Silahkan ketik “GAGAL” kemudian ketik tanda tutup kurung dan tekan Enter sehingga rumus IF menjadi seperti =IF(B2>=70,"LULUS","GAGAL")
    Cara menggunakan rumus if Excel
  6. Gunakan fitur AutoFill untuk menghitung nilai pada Cell B3 sampai B6 secara otomatis tanpa mengulangi penulisan rumus. Dan lihat hasilnya:
Cara menggunakan rumus if Tunggal Excel

Note: Ini hanya contoh paling sederhana. Mungkin Anda menemukan beberapa erorr atau memiliki tujuan lain. Mulai dari sini, mari kita pahami lebih lanjut tentang Fungsi IF ini.

#1 Rumus IF untuk Data Teks

Jika Anda ingin mengutip sebuah data berupa teks seperti LULUS, GAGAL, LIMA dan sebagainya ke dalam argument rumus Excel, maka teks tersebut wajib menggunakan kutip 2 menjadi “LULUS”, “GAGAL”, dan “LIMA”. Perhatikan contoh berikut:

Aturan Penulisan Fungsi IF

Gambar di atas memberikan contoh untuk mengutip teks kedalam argument rumus. Saya menggunakan fungsi =IF(A2=5,"Lima",6).

Lihat, argument value_if_true “Lima” menggunakan data berupa teks. Anda harus memberikan tanda kutip 2. Jika tidak, Excel akan memberikan hasil Pesan Error #NAME? seperti Cell B3

#2 Rumus IF untuk Data Angka

Pada Excel, ketika Anda mengutip sebuah angka atau pun cell kedalam argument rumus, Anda tidak perlu memberikan tanda kutip 2 seperti “27” dan “C5“. Kecuali jika Anda ingin Excel menganggap nilai tersebut sebagai teks.

Aturan Penulisan Fungsi IF

Sementara untuk data berupa angka, Anda tidak perlu mengapitnya dengan tanda kutip 2 seperti Rumus pada Cell B6 dan B7.

Kok bisa ? Karena Excel sudah mengenali data tersebut sebagai angka.

#3 Rumus IF untuk Data Cell

Aturan Penulisan Fungsi IF

Contoh ini menunjukkan Rumus IF yang mengambil hasil dari data dalam sebuah cell. Tujuan rumus IF tersebut adalah, jika Kolom A berisi A, maka 100. Jika bukan berisi A, maka 80.

Cell B10 dan B11 menunjukkan penggunaan yang benar dengan Rumus masing masing B10 =IF(A10="A",B17,B18) dan B11 =IF(A11="A",B17,B18)

Perhatikan argument logical_test terdapat data berupa Teks yaitu A10=“A” dan A11=“A”. Dengan memberikan kutip 2, Excel mengerti bahwa data tersebut berupa teks.

Coba lihat Rumus pada Cell B12 menunjukkan penggunaan yang salah karena tidak mengapit data teks pada logical test =IF(A12=A,B17,B18)

Selanjutnya, lihat argument value_if_true dan value_if_false. Kedua argument tersebut berisi sebuah reference cell yaitu B17 dan B18. Untuk data seperti ini, “Jangan apit dengan kutip 2”.

Sedangkan rumus pada Cell B13 menunjukkan penggunaan yang salah karena mengapit data berupa cell reference =IF(A13="A","B17","B18").

#4 Rumus IF Beda Sheet

Menggunakan Rumus IF untuk beda (antar) sheet sama saja dengan rumus lainnya. Anda akan melihat nama Sheet (ke 2 / 3 dan seterusnya) diterapkan kedalam argument rumus. Misalnya seperti contoh berikut:

Penting! Saya menggunakan fitur View Multiple WorkSheet untuk melihat banyak sheet secara bersamaan. Fitur ini sangat memudahkan penggunaan rumus beda sheet. Jika Anda belum tahu caranya, silahkan pelajari Panduan View Multiple WorkSheet Excel

Cara menggunakan Rumus IF Beda Sheet

Seperti yang Anda lihat, Saya memiliki 3 Sheet. Nama Sheet 1 = BedaSheet1, Sheet 2 = Beda Sheet2, dan Sheet 3 = Rekap IF. Kemudian, pada Cell C1, Saya menggunakan Rumus IF berikut:

Tulis Fungsi / Rumus IF:
=IF(BedaSheet1!A1=”Apel”,‘Beda Sheet2’!C1,“Cek Data”)

Artinya:
Jika nilai Pada Sheet BedaSheet1 Cell A1= Apel maka ambil nilai pada Sheet ‘Beda Sheet2 Cell C1 selain dari itu Cek Data

Lihat argument pada rumus tersebut. Excel menyertakan nama Sheet sumber sebelum nama cell seperti: =IF(BedaSheet1!A1="Apel",'Beda Sheet2'!C1,"Cek Data").

Namun perlu Anda perhatikan, jika nama sheet mengandung spasi, maka nama sheet dalam argument rumus harus diapit menggunakan kutip 1 ' ' seperti nama Sheet: =IF(BedaSheet1!A1="Apel",'Beda Sheet2'!C1 yang terdapat spasi antara teks “Beda” dengan “Sheet2”.

Penting! Aturan penulisan ini merupakan dasar dalam penggunaan Rumus Beda (antar) sheet di Excel. Pembahasan mendalam tentang Rumus Beda Sheet bisa Anda pelajari pada Panduan 3D Reference Excel

#5 Rumus IF Pada Format Table Bernama

Ketika Anda menggunakan Format Tabel Bernama, maka Anda bisa menggunakan Struktur Table sebagai reference dalam argument Rumus.

Menggunakan Struktur Table ke dalam reference argument rumus akan membuat rumus Anda lebih mudah dibaca.

Penting! Format Tabel Bernama tidak sama dengan Tabel menggunakan Border biasa. Mungkin masih ada beberapa pengguna yang keliru perihal ini. Jadi jika Anda ingin mempelajari tentang Table Bernama, silahkan kunjungi Panduan Membuat Tabel Excel

Misalnya, mungkin Anda pernah melihat Rumus IF seperti ini: =IF([@ANGKA]>=70,"LULUS","GAGAL") atau =IF(T_Nilai[@ANGKA]>=70,"LULUS","GAGAL").

Jangan bingung dengan argument pada Rumus tersebut. Karena argument [@Angka] dan T_Nilai[@ANGKA] merupakan struktur dalam sebuah tabel. Coba perhatikan gambar berikut:

Rumus IF pada Format Tabel Bernama

Cell C2 sampai C6 sama-sama menggunakan rumus ini: =IF([@ANGKA]>=70,"LULUS","GAGAL"). Begitu juga dengan cell G2 sampai G6 juga menggunakan rumus yang sama: =IF(T_Nilai[@ANGKA]>=70,"LULUS","GAGAL").

Meskipun menggunakan rumus yang sama, setiap baris memberikan hasil yang berbeda-beda. Inilah salah satu kelebihan Rumus Terstruktur pada tabel bernama.

Namun, penggunaan Rumus Terstruktur juga memiliki aturan penulisan tersendiri. Jangan sampai Anda mendapatkan hasil Error #VALUE! seperti hasil pada Cell G10 sampai G14.

Jadi sebelum menggunakan Rumus Terstruktur pada tabel, ada baiknya pahami terlebih dahulu Panduan Structured References Excel

Note: Saya harap Anda benar-benar memahami ke 5 contoh di atas sebelum melanjutkan ke contoh berikutnya (IF Bertingkat hingga Menggabungkan Rumus IF dengan rumus-rumus Excel lainnya.

Tentang value_if_false

Meskipun value_if_false adalah logika alternative. Namun, dalam penggunaan Rumus IF Tunggal maupun bertingkat, sering terjadi kesalahan pada argument value_if_false ini.

Misalnya, seperti contoh rumus IF Tunggal, kita menggunakan 1 logical_test, 1 value_if_true dan 1 value_if_false untuk menguji 2 kriteria yang berbeda.

Dalam beberapa keadaan, akan terjadi kesalahan. Coba Anda masukkan 1 atau 2 baris data yang baru pada Row 7 dan 8. Pada Cell B7 Saya isi dengan Teks “Belum Ada” dan Cell B8 dengan angka 257.

Kemudian AutoFill atau Copy Paste Rumus IF pada Kolom C untuk Row 7 dan 8. Lihat hasilnya:

Rumus IF menjadi error atau salah

Ada yang salah bukan ? Kenapa Excel memberikan hasil LULUS untuk Cell B7 dan B8 ? Padahal data tersebut tidak sesuai dengan kriteria yang ada.

Coba lihat kembali Rumus IF yang kita gunakan..

Tulis Fungsi / Rumus IF:
Cell B7 =IF(B7>=70,“LULUS”,“GAGAL”)
dan
Cell B8 =IF(B8>=70,“LULUS”,“GAGAL”)

Artinya:
Jika Nilai Pada Cell B7>=70 maka LULUS Selain dari itu GAGAL
dan
Jika Nilai Pada Cell B8>=70 maka LULUS Selain dari itu GAGAL

Pertama, Cell B8 yang menjadi logical_test berisi angka 257. Sementara kriteria logical_test pada rumus adalah >=70. Angka 257 lebih besar daripada 70, sehingga Excel memberikan hasil LULUS.

Kedua, cell B7 berisi teks “Belum Ada“. Bagaimana bisa nilai Belum Ada masuk kriteria LULUS ? Tentu bukan ini yang Anda inginkan.

Namun, Excel menganggap data berupa teks sebagai angka yang jauh lebih besar. Sehingga memberikan hasil LULUS.

Untuk mengatasi hal seperti ini, Anda bisa menggunakan Rumus IF Bertingkat “OR” Kriteria karena kita menguji 2 kriteria berbeda “LULUS atau GAGAL”.

Gunakan Rumus IF Bertingkat Or Kriteria

Atau, alternatif lain, Anda bisa menggunakan Data Validation pada Kolom B untuk membatasi pengisian data dengan syarat kolom tersebut hanya bisa diisi dengan Angka mulai dari 0 sampai 100.

Dengan cara ini, maka Rumus IF pada Contoh Pertama bisa Anda gunakan untuk mengatasi permasalahan ini tanpa menggunakan Fungsi IF bertingkat.

Penting! Tertarik untuk mempelajari Data Validation ? Silahkan Kunjungi BAB khusus Panduan Data Validation Excel.

Cara Menggunakan Rumus IF Bertingkat

Rumus IF bertingkat artinya menggunakan 2 atau lebih Fungsi IF dalam 1 cell. Teknik ini cocok Anda gunakan JIKA memiliki lebih dari 1 kriteria pengujian.

Saat ini ada 2 jenis Rumus IF bertingkat yang disebut IF “And” Kriteria dan IF “Or” Kriteria. Kedua jenis tersebut memiliki aturan penulisan yang berbeda-beda.

Agar bisa menggunakan Rumus IF bertingkat, perhatikan kembali setiap argument pada Rumus IF:

Tulis Fungsi / Rumus IF:
=IF(logical_test,[value_if_true],[value_if_false])

Rumus IF ke 2, 3 dan seterusnya bisa Anda masukkan pada argument [value_if_true] dan/atau [value_if_false] rumus IF sebelumnya.

Jika Anda memasukkan Rumus IF ke 2 pada argument [value_if_true], maka disebut juga IF “And” Kriteria. Jika pada [value_if_false], maka disebut juga IF “Or” Kriteria. Anda boleh menggunakan “And” kriteria saja, atau “Or” saja ataupun gabungan dari ke duanya.

Jika menggunakan “And” dan “Or” kriteria secara bersamaan, maka struktur rumus IF akan menjadi seperti berikut:

Tulis Fungsi / Rumus IF:
=IF(logical_test1,IF(logical_test2,[value_if_true2],[value_if_false2],IF(logical_test3,[value_if_true3],[value_if_false3]))

Ingat, IF “And” Kriteria menggantikan argument [value_if_true] dari Rumus IF Pertama (warna biru diganti dengan hijau).

Sementara IF “Or” kriteria menggantikan [value_if_false] dari Rumus IF pertama (warna biru diganti merah).

Biar semakin paham, coba pelajari satu per satu baik “And” kriteria maupun “Or” Kriteria dari penjelasan berikut:

#1 Rumus IF Bertingkat dengan “And” Kriteria

Note: “And” kriteria pada contoh ini bukan penggabungan Fungsi IF dengan Fungsi AND. Melainkan menggabungkan 2 atau lebih Fungsi IF untuk pengujian 2 atau lebih Syarat (kriteria) yang saling berhubungan.

Perhatikan aturan penulisan Rumus IF “And” Kriteria berikut:

Tulis Fungsi / Rumus IF “And” Kriteria:
=IF(logical_test1,IF(logical_test2,[value_if_true2],[value_if_false2]),[value_if_false1])

Perhatikan!, Fungis IF ke 2 (warna hijau) dimasukkan pada argument [value_if_true] dari rumus IF pertama (warna biru). Fungsi IF yang ke 2 juga harus berisi 3 argument dasar dari Rumus IF yang sudah Saya jelaskan pada awal Panduan ini yaitu logical_test, [value_if_true] dan [value_if_false].

Sementara itu, argument [value_if_false] dari rumus IF Pertama harus berada pada argument terakhir meskipun Anda menggunakan lebih dari 2 Rumus IF “And” Kriteria seperti berikut:

Tulis Fungsi / Rumus IF “And” Kriteria:
=IF(logical_test1,IF(logical_test2,IF(logical_test3,[value_if_true3],[value_if_false3]),[value_if_false2]),[value_if_false1])

Lihat, setiap Rumus IF mengisi argument [value_if_true] pada Rumus IF sebelumnya. Seperti IF ke 2 menggantikan [value_if_true] dari IF pertama. Begitu juga dengan IF ke 3 menggantikan [value_if_true] dari IF ke 2 dan begitu seterusnya.

Selain itu, Rumus IF ke 2 dan 3 juga memiliki 3 argument dasar (logical_test, [value_if_true], dan [value_if_false]).

Dan terakhir argument value_if_false1 dari rumus IF pertama. Jadi jangan lupakan aturan penulisan ini!

Contoh Soal Rumus IF Bertingkat “And” Kriteria

Mudah-mudahan maksud Saya bisa tersampaikan kepada Anda dengan contoh berikut:

Rumus IF bertingkat "And" Kriteria

Pada contoh ini, Siswa hanya dinyatakan LULUS jika memenuhi Standar Nilai Kelulusan Minimal untuk kedua Nilai (MID dan UAS).

Jika salah satu Nilai tidak memenuhi Standar Nilai Kelulusan Minimal, maka Siswa dinyatakan GAGAL. Berikut Standar Nilai Kelulusan Minimal:

  • Nilai MID = 75
  • Nilai UAS = 80

Anda bisa lihat, ada hubungan (And Kriteria) pada kedua Syarat tersebut yaitu Nilai MID dan UAS yang mana Siswa Harus Memenuhi Syarat Nilai Kelulusan Minimal untuk kedua nilai agar bisa dinyatakan LULUS.

Untuk contoh seperti ini, Anda bisa menggunakan Rumus IF “And” Kriteria dengan cara berikut:

Cara menggunakan rumus if bertingkat "And" Kriteria
  1. Masukkan Fungsi IF pertama beserta logical_test dan operator pemisah rumus ( , atau ; ). Dalam contoh ini menjadi =IF(B2>=75,
  2. Karena contoh ini menggunakan “And” Kriteria, maka Fungsi IF yang kedua dimasukkan tepat pada Argument value_if_true. Sehingga Rumus menjadi seperti berikut: =IF(B2>=75,IF(
  3. Masukkan logical_test beserta operator pemisah rumus ( , atau ; ) untuk Fungsi IF kedua. Sehingga Rumus menjadi =IF(B2>=75,IF(C2>=80,
  4. Masukkan value_if_true beserta operator pemisah rumus ( , atau ; ) Sehingga rumus menjadi =IF(B2>=75,IF(C2>=80,"LULUS",
  5. Masukkan value_if_false, tanda tutup kurung dan operator pemisah rumus ( , atau ; ) untuk Fungsi IF Kedua sehingga menjadi =IF(B2>=75,IF(C2>=80,"LULUS","GAGAL"),
    value_if_false pada tahap ini akan mengkonfirmasi jika logical_test pada Fungsi IF kedua tidak memenuhi kriteria, maka Excel akan memberikan hasil “GAGAL”. Dan sampai tahap ini, Fungsi IF ke dua sudah ditutup (tanda tutup kurung).
  6. Masukkan value_if_false dan tanda tutup kurung untuk Fungsi IF pertama sehingga menjadi =IF(B2>=75,IF(C2>=80,"LULUS","GAGAL"),"GAGAL") kemudian tekan Enter dan lihat hasilnya:
cara menggunakan fungsi if bertingkat "And" Kriteria

Apa Makna Fungsi IF Yang Digunakan ?

Sedikit Saya jelaskan tentang Fungsi IF yang digunakan:

Tulis Rumus / Fungsi:
=
IF(B2>=75,IF(C2>=80,“LULUS”,“GAGAL”),“GAGAL”)

Artinya:
Jika
B2>=75 Dan Jika C2>=80 Maka LULUS jika salah satu tidak terpenuhi maka GAGAL jika semua tidak terpenuhi maka GAGAL

Dengan Rumus ini, pertama-tama Excel akan menguji apakah cell B5>=75 dari logical_test pertama =IF(B2>=75,.

Kemudian, apabila pengujian logical_test sesuai kiteria, maka Excel akan memberikan hasil Rumus IF kedua =IF(B2>=75,IF(C2>=80,. Karena Rumus IF kedua berada pada value_if_true Rumus IF pertama.

Selanjutnya, apabila pengujian logical_test Rumus IF kedua memberikan hasil sesuai kriteria maka Excel memberikan hasil value_if_true dari Fungsi IF kedua =IF(B2>=75,IF(C2>=80,"LULUS",.

Namun, apabila pengujian tidak sesuai kriteria, maka Excel menggunakan hasil value_if_false rumus kedua =IF(B2>=75,IF(C2>=80,"LULUS","GAGAL"),.

Apabila Anda tidak mengisi value_if_false untuk fungsi IF kedua, maka Excel akan memberikan hasil FALSE seperti gambar berikut:

cara menggunakan fungsi if bertingkat "And" Kriteria

Selanjutnya, value_if_false terakhir =IF(B2>=75,IF(C2>=80,"LULUS","GAGAL"),"GAGAL") berguna apabila logical test rumus IF pertama tidak sesuai kriteria. Jika argument ini tidak di isi maka Excel memberikan hasil FALSE seperti gambar:

cara menggunakan fungsi if bertingkat "And" Kriteria

Bagaimana ? Mudah bukan ? FYI, Anda bisa menggunakan banyak sekali kriteria ke dalam Fungsi IF “And” kriteria ini.

Yang terpenting, masukkan Fungsi IF selanjutnya pada argument value_if_true fungsi IF sebelumnya. Kemudian jangan lupa mengisi semua value_if_false Fungsi IF yang digunakan jika Anda tidak ingin Excel memberikan hasil FALSE.

Selain itu, setiap Fungsi IF yang Anda gunakan, Wajib ditutup (tanda tutup kurung) apabila semua argument yang dibutuhkan sudah diisi. Jika Anda keliru dibagian ini, besar kemungkinan akan terjadi kesalahan pada Rumus IF.

#2 Rumus IF Bertingkat dengan “Or” Kriteria

Note: “Or” kriteria pada contoh ini juga bukan penggabungan Fungsi IF dengan Fungsi OR. Melainkan menggabungkan 2 atau lebih Fungsi IF untuk pengujian 2 atau lebih Syarat (kriteria) yang tidak berhubungan.

Rumus IF Bertingkat Excel dengan “Or” Kriteria merupakan kebalikan dari “And” kriteria. Perbedaannya, “Or” Kriteria tidak memberlakukan syarat dalam satu hubungan. Sementara Syarat pada “And” kriteria berhubungan satu sama lain.

Perbedaan lainnya, pada IF bertingkat “And” Kriteria, Fungsi IF kedua dan seterusnya dimasukkan pada argument value_if_true.

Sementara pada Rumus IF bertingkat “Or” Kriteria, Fungsi IF kedua dan seterusnya dimasukkan pada argument value_if_false.

Jangan bingung… Coba perhatikan aturan penulisan Rumus IF “OR” Kriteria berikut:

Tulis Fungsi / Rumus IF “Or” Kriteria:
=IF(logical_test1,[value_if_true1],IF(logical_test2,[value_if_true2],[value_if_false2]))

Fungsi IF ke 2 ini menggantikan peran [value_if_false] rumus IF yang pertama. Jadi jika pengujian pada Logical_test1 memberikan hasil true (benar / memenuhi kriteria), maka Excel memberikan hasil dari argument [value_if_true1]. Jika tidak, maka Excel akan melakukan pengujian kembali menggunakan fungsi IF ke 2.

Inilah makna dari Or kriteria tersebut.

Bagaimana jika Saya menggunakan lebih dari 2 Rumus IF bertingkat “Or” kriteria ? Yaa… Kurang lebih struktur rumus akan seperi ini:

Tulis Fungsi / Rumus IF “Or” Kriteria:
=IF(logical_test1,[value_if_true1],IF(logical_test2,[value_if_true2],IF(logical_test3,[value_if_true3],[value_if_false3])

Setiap Rumus IF mengisi argument [value_if_false] pada Rumus IF sebelumnya. Seperti IF ke 2 menggantikan [value_if_false] dari IF pertama. Begitu juga dengan IF ke 3 menggantikan [value_if_false] dari IF ke 2 dan begitu seterusnya.

Struktur ini akan memerintahkan Excel untuk melakukan pengujian dari Rumus IF 1. Jika tidak memenuhi kriteria, maka menggunakan IF ke 2. Jika tidak memenuhi kriteria juga, maka menggunakan IF ke 3. Terakhir, jika tidak memenuhi kriteria juga, maka menggunakan argument [value_if_false3].

Note: Tentunya Anda juga bisa menambahkan IF ke 4 untuk menggantikan argument [value_if_false3] jika dibutuhkan. Dan begitu pula seterusnya jika menambahkan IF “Or” kriteria selanjutnya.

Nah, sekarang kita coba masuk ke contoh soal…

Contoh Soal Rumus IF Bertingkat “Or” Kriteria

Rumus IF Bertingkat / bertumpuk / berganda ini bisa Anda jadikan alternatif dari contoh Pertama di awal artikel Panduan ini.

Sebelumnya, kita menggunakan Rumus IF berikut:

Tulis Fungsi / Rumus IF:
=IF(B7>=70,“LULUS”,“GAGAL”)

Rumus tersebut cenderung menghasilkan kesalahan apabila kolom B berisi data lebih besar dari 100 atau data dengan tipe bukan angka.

Saya ulangi kriteria pada contoh tersebut: “Kita akan menentukan mata kuliah mana yang masuk dalam kategori LULUS. Perhatikan syarat yang Saya gunakan:”

  • Nilai 70 sampai 100 adalah LULUS
  • Nilai kecil dari 70 adalah GAGAL

Terlihat ada 2 kriteria yang tidak saling berhubungan. Dan syarat pengujian adalah sebuah angka.

Disinilah kunci utamanya. Karena kriteria berupa angka, Saya sarankan lakukan pengujian mulai dari angka terkecil hingga terbesar.

Dalam contoh ini, mulailah pengujian dari kriteria: Nilai <70 adalah Gagal. Kemudian dilanjutkan dengan nilai berikutnya. Sehingga Rumus IF Bertingkat “Or” Kriteria akan tampak seperri berikut:

Gunakan Rumus IF Bertingkat Or Kriteria

Apa Makna Fungsi IF “Or” Kriteria ini ?

Tulis Rumus / Fungsi:
=IF(B7<70,“GAGAL”,IF(B7<=100,“LULUS”,“DATA SALAH”)

Artinya:
Jika Nilai pada Cell B7<70 maka GAGAL ATAU Jika Nilai pada Cell B7<=100 maka LULUS Selain Dari Itu DATA SALAH

Saya jelaskan makna Fungsi tersebut… Sambil Anda memperhatikan Arti fungsi yang Saya tulis di atas.

Pertama-tama, Excel akan melakukan pengujian Logical_test =IF(B7<70, kemudian apabila (benar) Nilai pada Cell B7 lebih kecil dari 70, maka Excel memberikan hasil value_if_true pada Fungsi pertama =IF(B7<70,"GAGAL" dan Berhenti melakukan pengujian sampai tahap ini (Fungsi IF kedua diabaikan). Hasil ini bisa Anda lihat pada Row 4 dan 6 (lihat gambar)

Namun, apabila nilai pada Cell B7 tidak lebih kecil dari 70 (misal lebih besar atau isi cell tersebut berupa teks dll), maka Excel akan memberikan hasil dari value_if_false (rumus IF pertama).

Sementara pada Rumus ini, value_if_false (pada Rumus IF Pertama) diisi dengan Rumus IF kedua =IF(B7<70,"GAGAL",IF(B7<=100,"LULUS","DATA SALAH".

Dengan demikian Excel akan menggunakan Fungsi IF kedua untuk pengujian selanjutnya.

Dan Excel melakukan pengujian logical_test (Rumus IF Kedua) seperti biasa. Apabila logical_test benar, maka hasilnya value_if_true =IF(B7<70,"GAGAL",IF(B7<=100,"LULUS", Hasil ini bisa Anda lihat pada Row 2, 3, dan 5.

Sementara itu, apabila logical test salah, maka hasilnya value_if_false =IF(B7<70,"GAGAL",IF(B7<=100,"LULUS","DATA SALAH" lihat hasilnya pada Row 7 dan 8.

Bagaimana ? Mudah bukan ? Yang terpenting….

PAHAMI ATURAN PENULISAN RUMUS IF TERLEBIH DAHULU SEBELUM MENGGUNAKAN FUNGSI IF BERTINGKAT

Rolan mardani

Apakah Anda ingin meletakkan Fungsi IF kedua pada argument Value_IF_True atau argument Value_IF_False. Itu semua tergantung tujuan Anda.

Bahkan Anda juga bisa menggabungkan Fungsi IF Bertingkat “And” kriteria dengan “Or” Kriteria dalam 1 Rumus.

Cakupan Fungsi IF Excel

Rumus IF Excel sering gagal bila terdapat kesalahan dalam penulisan fungsi nya. Untuk dapat memaksimalkan penggunaannya berikut beberapa hal yang mesti Anda ketahui mengenai fungsi IF pada Excel ini:

  1. Pahami setiap aturan penulisan fungsi IF agar mengurangi resiko kesalahan dalam memasukkan rumus.
  2. Rumus IF pada excel dapat digabungkan mencapai 64 tingkatan. Jika Anda membutuhkan tingkatan yang lebih, Anda bisa menggunakan rumus LOOKUP, HLOOKUP, VLOOKUP, atau CHOOSE.
  3. Selain fungsi IF, Anda juga dapat menggunakan fungsi lainnya di Ms. Excel untuk  mengolah data berdasarkan kriteria tertentu seperti COUNTIF atau COUNTIFS untuk menghitung banyak data di dalam suatu range dan ada juga fungsi SUMIF atau SUMIFS untuk menjumlahkan (total) dalam suatu range tertentu dengan beberapa syarat.
  4. Rumus IF juga dapat digabungkan dengan fungsi-fungsi lainnya seperti LEFT, RIGHT, dan MID dll.

Bila konten ini bermanfaat, yuuk share ke sosial media untuk membantu teman lainnya yang membutuhkan.

Jika ada pertanyaan mengenai penggunaan rumus IF excel ini, Silahkan coret-coret di kolom komentar.

Pintasan Panduan Logical Function Excel

Bab sebelumnya: COUNT & SUM.

  1. Logical: Jenis-jenis Fungsi logika (IF, AND, OR, NOT) dan cara menggunakannya (Level dasar).
  2. Comparison Operators: Operator Pembanding untuk Fungsi Logical (seperti sama dengan “=”, lebih besar dari “>”, lebih kecil dari “<“, tidak sama dengan “<>”, dll).
  3. IF Function: (Anda Disini).
  4. IF Bertingkat 3 Kondisi (Atau Lebih): Cara menggunakan rumus IF dengan 3 kondisi (kriteria) + Alternatif Penggunaan Terbaik.
  5. Kombinasi IF + AND: Cara menggabungkan Rumus IF + Rumus AND (Tunggal dan Bertingkat). Dapatkan pemahaman mendalam.
  6. OR: Contoh menggunakan Fungsi OR (Lengkap). Gabungan IF + OR, AND + OR, OR + WEEKDAY, dan XOR.

Bab berikutnya: Date & Time.

49 tanggapan pada “Rumus IF Excel Tunggal dan Bertingkat [Aturan + 7 Contoh]”

  1. gimana caranya jika mengkonversi Text menjadi Angka dengan menggunakan Fungsi IF. Misalnya saya ingin mendapatkan data tentang jenjang pendidikan responden. Masing-masing jenjang responden yang memberi jawaban saya beri skor. Jika menjawab S3 saya beri skor 30, S2:25, S1:15, D3:10, D2/SLTA::5, <SLTA:1. Gimana cara konfigurasi rumus IF untuk persoalan saya ini? Apakah bisa seperti ini: =IF(G2=”S3″,30; IF(G2=”S2″,25; IF(G2=”S1″,15; IF(G2=”D3″,10; IF(G2=”D2″,5; 1))))). Terima Ka

  2. Ada 2 point yang akan saya bahas

    1. Tanda pemisah
      Perhatikan tanda pemisah fungsi nya pak. Yang itu loh koma (,) dan titik koma (;).
      Sesuaikan dengan format yg di gunakan di perangkat bapak.
      Kalau pakai titik koma, ya pakai titik koma semua.
      Contoh pakai titik koma
      =IF(G2=”S3″;30;IF(G2=”S2″;25;IF(G2=”S1″;15;IF(G2=”D3″;10;IF(G2=”D2″;5;1)))))
      Begitu juga jika pakai tanda koma.

    2. Desain File
      Saya belum tergambar model data yang bapak gunakan.
      Pakai fungsi excel tergantung kondisi pak.
      Misal..
      Jika responden melakukan input data pada cell G2.
      Sedangkan bapak ingin menampilkan konversi data pada cell G2 juga.
      Maka fungsi if saja tidak efektif digunakan. Lebih baik gunakan gabungan condition formating dan fungsi if

    Kondisi ke 2
    Responden input data pada cell F2.
    Bapak ingin menampilkan hasil konversi di cell G2.
    Kondisi ini bisa menggunakan fungsi if.

  3. IF(B7<1583;IF(B6<11;IF(B5<4;0;IF(B5>14;2+INT(B41/4)-B41;”TANGGAL SALAH”));2+INT(B41/4)-B41);2+INT(B41/4)-B41)

    Kalau rumus ini penjabarannya bagaimana?

  4. Selamat malam boss,, maaf sy mo minta pencerahannya!!
    Sy ingin ngerekap jumlah laki2 berdasarkan kelompok umur tetapi akan berkurang secara otomatis atau pun tidak terinput jika laki2 tersebut meninggal,, seperti apa rumusnya,, trmksih sebelumnya..

  5. selamat malam, mau tanya, saya mempunyai sebuah kasus, saya ingin mengambil hasil dari sebuah sel yg berisi fungsi RIGHT/MID/LEFT untuk digunakan sebagai logika tes dalam fungsi IF, namun setelah saya praktekkan hasil fungsi IF menunjukkan “Salah” padahal logika tesnya benar, contoh, saya mengambil 1 karakter dari sel A5 yg berisi string teks ke sel B5 dengan fungsi LEFT, kemudian di sel C5 saya gunakan hasil dari fungsi LEFT pada sel B5 untuk dijadikan logika tes dengan sebuah string di sel A4 untuk menentukan apakah benar/salah, namun hasil yg muncul pada sel C5 salah, padahal pada kenyataannya seharusnya benar, mungkin bisa di bantu untuk tipsnya, atau jika ada fungsi lain selain IF, bisa dibagikan di sini, terima kasih

  6. Ga bisa diraba-raba mas.

    Oh ya Cell A4 untuk apa mas ?
    Hmm.. Coba screenshot datanya, terus ubah screenshot nya menjadi link di Website prnt.sc
    terus copy paste link nya ke komentar. Sampai kan tujuannya apa dan dari data apa.

  7. Selamat pagi,
    Mau tanya gimana caranya membuat rumus
    =IF(kolom nilai=”kolom nilai” ;”tanda centang” ;””)
    Yang mau saya tanyakan cara ngetik tanda centang pada rumus itu bagaimana.
    Terimakasih sebelumnya, mohon kesediaan ya untuk memberi jawabannya

  8. Lebih bagus pake conditional Formatting sih kak.
    Tapi kalo tetap mau pake Rumus IF, coba copy rumus ini ke formula bar.
    =IF(Kolom Nilai="Kolom Nilai";"✓";"")
    Cara Ke 2:
    Kalo mau hasil rumus IF ini bisa dikenali Excel, pake font wingdings2 + Rumus ini:
    =IF(Kolom Nilai="Kolom Nilai";"P";"")
    Panduan lengkapnya Kunjungi Panduan Check Mark Excel

  9. Selamat siang, saya ada kendala untuk bikin rumusnya
    ada 2 barang dengan kode item, nama item, jumlah item, dan harga
    pada item pertama ( Kode : MK01, Nama item : Genji) (harga : jika beli di atas >=10;”2000″;”5000″
    Pada item ke dua ( Kode : MK02. Nama item : pimco) ( harga : jika beli di atas >=10 makan 4000″;”7000)

    saya mau buat cara cepatnya dengan menuliskan kode item dan jumlah item yg di beli saja maka hasil akan keluar

    apakah bisa ya?terimakasih

  10. Lebih Efisien kalo pake VLOOKUP mas Panji. Tapi kalo item nya cuma 2 dan mas Panji mau pake Rumus IF, bisa juga kok.
    Misalnya data tersusun pada Kolom A (Kode), B (Nama Item), C (Jumlah Item), dan D (Harga).
    Item 1 (yaitu MK01 terletak pada Cell A2. Selanjutnya sesuai dengan urutan kolom di atas.
    Coba gunakan Rumus IF berikut untuk kolom B (Nama Item).
    =IF(A2="MK01";"Genji";IF(A2="MK02";"Pimco";"Kode Salah"))
    Terus gunakan rumus berikut untuk data pada Kolom D (Harga):
    =IF(AND(A2="MK01";C2>=10);2000;IF(AND(A2="MK01";C2<10);5000;IF(AND(A2="MK02";C2>=10);4000;IF(AND(A2="MK02";C2<10);7000;"Data Salah"))))
    Note: Silahkan sesuaikan operator pemisah rumus (tanda , atau ; ) dengan pengaturan komputer mas Panji.
    dan sesuaikan Operator Perbandingan rumus. Saya menggunakan kriteria jika beli 10 atau lebih (>=), maka akan mendapatkan potongan sesuai kode item.

  11. selamat malam, mau nanya.kak
    ini rumus nya gimana
    “jika nilai 1 dan nilai 2 >= 70 maka lulus, jikak tidak maka gagal”
    nilai 1 : 67
    nilai 2 : 80
    terima kasih kak

  12. Gabungan Rumus IF dan AND kak.
    Misalnya, Nilai 1 ada di Cell D1. Dan Nilai 2 ada di Cell E1. Jadi rumus nya:

    =IF(AND(D1>=70,E1>=70),"Lulus","Gagal")

    Note:
    Silahkan sesuaikan operator pemisah rumus yang digunakan komputernya ya (tanda , atau ; )

  13. Tanda sama dengan itu sama seperti konsep matematika.
    “>” artinya Lebih Besar Dari …
    “>=” artinya Lebih Besar Dari Atau Sama Dengan
    Jadi kalo >90, maka hanya nilai yang lebih besar dari 90 yang masuk kriteria. Misal, 90,1 atau 90,2 dst…
    Kalo >=90, maka nilai 90 atau nilai yg lebih besar akan masuk kriteria.

  14. Cara buat keterangan pake rumus if KK, tp nilai datanya berupa huruf.
    Gimana cara pengerjaan nya??

  15. Masukkan huruf itu ke dalam rumus (yang tipe data) argument logical_test.
    Misal, Cell A1 dan A2 berisi dua tiga dan empat puluh
    Pengujian:
    Jika dua tiga, maka Yes
    Jika empat puluh, maka No
    Jadi rumus IF untuk Cell A1, =IF(A1="dua tiga","Yes",IF(A1="empat puluh","No"))
    Note: Sesuaikan operator pemisah rumus (tanda , dan ; )

  16. Selamat Sore,

    Mau tanya kenapa hasil dari rumus IF bertingkat berupa angka tidak bisa di sum ya?

  17. Sore KK, kalo hasil yg di tunjuk berupa tulisan yg SDH ada dikolom bagaimana caranya, misal :
    A2(1) B2(L) C2(detergen)
    A3(1) B3(S). C3(tinta)
    A4(2) B4(L). C4(pewangi)

    Di kolom
    D2 saya ingin jawaban
    Jika B2:B4 adalah L, dan A2:A4 adalah 1 maka (tulis isi C2)

    D3 saya ingin jawaban
    Jika B2:B4 adalah L, dan A2:A4 adalah 2 maka (tulis isi C3)

    D4 saya ingin jawaban
    Jka B2:B4 adalah L, dan A2:A4 adalah 3 maka (tulis isi C4)

    Terimakasih ka

  18. Mohon bantuan dan koreksinya masih salah:

    =IFERROR(IF(D6=”Supplier”;VLOOKUP(E6;SupplierTable;2;0);VLOOKUP(E6;
    CustomerTable;2;0);VLOOKUP(E6;PiutangUSPTable;2;0);VLOOKUP(E6;HutangAnggotaTable;2;0);VLOOKUP(E6;PiutangDATable;2;0);VLOOKUP(E6;SukarelaTable;2;0);VLOOKUP(E6;SimsusTable;2;0);VLOOKUP(E6;TabsusTable;2;0);VLOOKUP(E6;SimpokTable;2;0);VLOOKUP(E6;SiwajTable;2;0))))))))));””)

    dan

    =IF(ARAPLedgerCat=”Supplier”;IF(AND(G10=ARAPControl;L10=ARAPLedgerCode);VALUE(C10&G10);”ARAPCode”);IF(AND(G10=ARAPControl;M10=ARAPLedgerCode);VALUE(C10&G10);”ARAPCode”))
    Mau ditambah :
    PiutangDATable . >>>>> Pada kolom/Baris L10
    CustomerTable >>>>>>>Pada kolom/Baris M10
    PiutangUSPTable >>>>>>>>> Pada kolom/Baris N10
    HutangAnggotaTable >>>>>>Pada kolom/Baris O10
    SupplierTable >>>>>>>>>> Pada kolom/Baris P10
    SukarelaTable >>>>>>>>Pada kolom/Baris Q10
    SimsusTable >>>>>>>>> Pada kolom/Baris R10
    TabsusTable >>>>>>>>> Pada kolom/Baris S10
    SimpokTable >>>>>>>>> Pada kolom/Baris T10
    SiwajTable >>>>>>>>>>> Pada kolom/Baris U10

  19. Mungkin maksud kakak begini kali ya (contoh rumus untuk cell D2).
    Jika B2 adalah L dan A2 adalah 1, maka C2. Maksud C2 ini adalah untuk menampilkan nilai pada Cell C2 jika kriteria terpenuhi. kalo gitu, coba rumus if ini:
    =IF(AND(B2="L",A2=1),$C$2,IF(AND(B2="L",A2=2),$C$3,IF(AND(B2="L",A2=3),$C$4,"Ada yang Salah")))
    Note:
    Sesuaikan operator pemisah rumus ( , atau ; )
    Saya menggunakan reference absolute (lambang $) pada cell C2, C3 dan C4 menjadi $C$2, $C$3, dan $C$4. Pastikan udah paham penggunaan reference absolute. Jika belum, coba kunjungi Panduan Cell Reference Excel

  20. Kedua rumus kakak ini terkait dengan pembahasan Fungsi IF Bertingkat / Berganda diatas.
    Coba pahami aturan penulisan rumus nya biar tidak terjadi kesalahan. Saya jelaskan dengan contoh rumus yang pertama.
    =IFERROR(IF(D6=”Supplier”;VLOOKUP(E6;SupplierTable;2;0);VLOOKUP(E6;CustomerTable;2;0)
    Sebatas ini, hanya memenuhi ke-3 argument pada fungsi If (logical_test, value_if_true dan value_if_false)
    Sementara ada banyak argument lain setelahnya yang tidak jelas menggunakan fungsi apa seperti VLOOKUP(E6;PiutangUSPTable;2;0)...(dan seterusnya)...
    Solusinya, (sementara saya hapus IFERROR nya ya)…
    IF(D6=”Supplier”;VLOOKUP(E6;SupplierTable;2;0)
    Sebatas ini, hanya memenuhi logical_test dan value_if_true… Karena ada banyak kriteria yang diinginkan, maka tambahkan fungsi IF yang ke 2 menjadi.. IF(D6=”Supplier”;VLOOKUP(E6;SupplierTable;2;0);IF(D6=”bla-bla-bla”;
    Note:
    IF(D6=bla-blabla”; adalah fungsi IF ke dua dan juga wajib menggunakan logical_test. Dalam contoh ini adalah D6=”bla-bla-bla” bisa diganti dengan nilai yang dibutuhkan dan tidak boleh sama dengan logical_test pada fungsi IF lainnya. Kemudian barulah masukkan argument value_if_true untuk rumus IF yang ke dua menjadi:
    IF(D6=”Supplier”;VLOOKUP(E6;SupplierTable;2;0);IF(D6=”bla-bla-bla”;VLOOKUP(E6;CustomerTable;2;0)
    Sampai disini, bisa ditambahkan fungsi IF yang ke 3 dan seterusnya untuk argumen lainnya sesuai kebutuhan.
    Gitu alur nya kak.
    Coba dibaca lagi bagian IF Bertingkat “Or” Kriteria diartikel diatas ya kak.

  21. Bagaimana Rumus kalau saya ingin membuat rumus seperti ini :
    – N < 3 maka ABC
    – N 3-4 maka DEF
    – N 4-6 maka GHI
    – N 7-9 maka JKL

  22. Kriteria untuk N 3-4 , N 4-6 dan N 7-9 agak membingungkan. Saya artikan begini ya..
    Jika N adalah 3 sampai 4, maka DEF. Jika N adalah lebih besar dari 4 sampai 6, maka GHI. Terkahir, jika N lebih besar dari 6 sampai 9 adalah JKL.
    Terus katakanlah N adalah Cell A2. Coba pake rumus ini:
    =IF(A2<3,"ABC",IF(A2<=4,"DEF",IF(A2<=6,"GHI",IF(A2<=9,"JKL","Data Salah"))))
    Cek Hasil, klik disini

  23. Giamana penulisan rumusnya jika
    jika C5=10 maka hasil di kolom D5 adalah 0, jika C5>10 maka dikolom D5 adalah C5*10%

  24. Coba =IF(C5=10,0,IF(C5>10,C5*10%,"-"))
    Jika hasilnya – , artinya nilai pada Cell C5 lebih kecil dari 10.
    Jika hasilnya #VALUE!, artinya nilai pada cell C5 tidak berisi angka valid, seperti berisi teks / simbol / gabungan teks & simbol dll..

  25. saya memiliki data nilai pre dan post test dan akan membaginya dalam kelompok2 tertentu, bagaimana rumus IF nya ya?
    Jika:
    Pre Post Penamaan
    0-50 0-50 Deadwood
    50-100 0-50 Inconsistent
    0-100 50-75 Continuity Player
    0-75 75-100 High Profesional
    75-100 75-100 Consistence Star

  26. Coba gabungkan Fungsi IF dan AND. Setidaknya pake 5 tingkat Fungsi IF.
    Fungsi AND digunakan sebagai argument logical_test pada setiap fungsi IF.
    Sementara Fungsi IF yang ke 2, 3, 4 dan 5 digunakan sebagai argument value_if_false pada Fungsi IF sebelumnya.
    Saran Saya, pahami range data yang dijadikan kriteria dalam rumus baik untuk Pre atau Post test. Biar lebih mudah memahami penggunakan operator perbandingan (>, =, <, >=, <= dll). Saya bisa dapet hasil pake rumus ini (dengan anggapan, data pre test pada Cell E4 dan Post test pada cell F4) =IF(AND(E4>=0,E4<=50,F4>=0,F4<=50),"Deadwood",IF(AND(E4>=50,E4<=100,F4>=0,F4<=50),"Inconsistent",IF(AND(E4>=0,E4<=100,F4>=50,F4<=75),"Continuity Player",IF(AND(E4>=0,E4<=75,F4>=75,F4<=100),"High Profesional",IF(AND(E4>=75,E4<=100,F4>=75,F4<=100),"Consistence Star","Data Salah")))))

    UPDATE
    Setelah Saya cek berkali-kali, ternyata ada kekeliruan kriteria yang digunakan (Pre dan Post) yang menyebabkan hasil tidak konsisten.
    Sebetulnya khusus case ini bisa diselesaikan dengan gabungan Fungsi IF + AND.
    Saya sudah buatkan panduan khusus tentang ini. Silahkan cek SUB-BAB Kombinasi IF + AND (Lihat Pintasan Panduan).

  27. ass.wr.wb, saya juga lagi buat aplikasi untuk koperasi. bisa nyonto nggak buat bahan perbandingan,,

  28. Rumus untuk menentukan Kategori A untuk nilai UAS (F2) lebih dari atau sama dengan 80, kategori B untuk nilai lebih dari atau sama dengan 70, kategori C untuk nilai lebih dari 60, kategori D untuk nilai lebih dari 50, dan kategori E untuk nilai kurang dari atau sama dengan 50 adalah

    Penjelasan di atas rumus bagaimana?

  29. Gunakan Rumus IF Bertingkat “Or” Kriteria di atas.
    Kriteria pengujian yg mas butuhkan kan ada 5 tuh. Jd gabungkan 5 rumus IF Bertingkat. Yg “Or” kriteria ya…
    Kriteria pengujiannya buat aja berurutan sesuai pertanyaan mas.
    Jd untuk logical_test IF pertama, pake >=80
    Logical_test IF yg ke 2 pake >=70
    Begitu seterus nya sampe logical_test IF yg ke 5 pake <=50 Jd pahami dahulu penulisan nya ya.. biar makin paham.

  30. Sutrisno Al Hazim

    mau nanya min,
    Total Cost (F7)
    Shipping (G7)

    cara buat rumus ini min:
    1. Tidak ada biaya shipping untuk penjualan (total cost) lebih dari $1,500; selain dari itu – 2% dari total cost?
    terimakasih min

  31. Pake IF tunggal maupun bertingkat “Or” kriteria pun bisa.
    Untuk logical test, gunakan angka nya saja (abaikan simbol mata uang)
    =IF(F7>1500,0,IF(F7<=1500,2%*F7,""))

  32. Pak R Mardani, apakah ada fungsi di excell yang bisa melakukan perhitungan continue sampai data nya cocok.

    Misal nya. Cell C4 = 4. Cell C5 = 0. Cell C6 = 0.

    Saya mau excell menambah otomatis cell C5 dengan angka 1 sampai sama nilainya dengan C4. Pada saat yang sama nilai di Cell C6 juga bertambah otomatis dengan angka 2. Ketika C4 = C5 otomatis perhitungan berhenti. Dari situ saya mau tahu berapa nilai C6.

  33. Seneng saya lihat banyak yang belajar terkait excel gan, saya ijin belajar juga ya
    kalo rumus untuk menentukan dengan banyak hasil kriteria muncul bagaimana ya
    1. jika A = 100 maka hasilnya Full AR
    2. Jika A <=100 maka hasilnya adalah Bukti potong
    3. jika A = 100 dan A = 01 adalah petani maka hasilnya Full AR Petani
    4. jika A <=100 dan A = kode 02 adalah peternak maka hasilnya Bukti Potong Peternak

    beginilah kendala saya,…..jadi secara nilai saya tahu itu Full AR dan Bukti potong dan secara kode saya tahu itu yang melakkukan sehingga muncul pada keterangan seperti hasil

    thanks ya gan

  34. Silahkan mas…

    Saya rasa kriteria pengujiannya perlu dibenahi lagi mas. Belum tergambar jelas tentang Data apa yang dimiliki dan diuji serta hasil seperti apa yang diinginkan.

    Saya lihat… Kriteria 1 dan 2 itu saling tumpang tindih.

    Maksudnya begini…

    Untuk kriteria 1, A=100. Kalo nilai yang diuji adalah 100, maka hasilnya Full AR.
    Sedangkan kriteria 2, A<=100.

    Ini artinya nilai yang lebih kecil dari atau sama dengan 100 adalah Bukti Potong. Jadi nilai 100 pun juga termasuk benar dalam kriteria ke 2 ini.

    Sama saja kan dengan kriteria 1 ? Tapi hasil yang diinginkan dari kriteria 1 dan 2 berbeda. Ini Tidak bisa… Karna kriteria yang diuji hanya ada 1. Cuma uji kriteria A.

    Beda dengan kriteria ke 3 dan 4. Data yang diuji ada 2. Yaitu Nilai pada Kolom A dan Kode. Ini bisa saja pake kriteria agan diatas. Hanya saja, Saya nilai Kode ini lebih baik dipisah dari nilai pada kolom A.

    Selain itu juga… Saya rasa kriteria 1 dan 2 tidak cukup bagus digabungkan dengan kriteria 3 dan 4.

    Sedikit Saya sesuaikan meskipun tidak sempurna…

    1. Jika A=100, maka Full AR
    2. Jika A<100, Bukti Potong
    3. Jika A=100 dan B=01, maka Full AR Petani.
    4. Jika A<=100 dan B=02, maka Bukti Poting Peternak.

    Summary, untuk case ini gunakan rumus IF bertingkat “Or” Kriteria serta gabungkan dengan Fungsi AND.
    =IF(AND(A1=100,B1=”01″),”Full AR Petani”,IF(AND(A1<=100,B1="02"),"Bukti Potong Peternak",IF(A1=100,"Full AR",IF(A1<100,"Bukti Potong","Tidak Sesuai Kriteria"))))

    Note: Rumus diatas belum bisa dikatakan final… Karena kriteria yang digunakan belum betul-betul bisa menggambarkan data yang digunakan serta tujuan yang diinginkan.

    Coba scroll kebagian Pintasan Panduan diatas gan… Coba baca-baca SUB BAB Kombinasi IF + AND. Itu contoh yang Saya angkat dari salah satu komentar pengunjung M Jurnal.

    Mulai dari pembenahan kriteria yang digunakan hingga menyelesaikan tujuan dengan kombinasi rumus.

  35. selamat siang, maaf mau bertanya,
    jika menggunakan rumus if pada range tabel data berupa teks apakah format nya sama?
    misal terdapat data
    A1 = Yes,
    A2 = Yes,
    A3 = No,
    A4 = Yes,
    A5 = Yes
    kemudian di cari nilai A7 yng mengharuskan jika A1..A5 “Yes” maka tampilkan “Passed”, jika salah 1 nya “No” maka tampilkan “Failed”,
    karena saya menggunakan rumus =IF(P7:P12=”Yes”, “Passed”, “Failed”) hasil nya masih tetap “Passed”
    apakah ada yng kurang pada rumus IF yng saya gunakan?

  36. Coba gunakan kombinasi IF, COUNTIF, dan COUNTA.

    =IF(COUNTIF(A1:A5,”Yes”)=COUNTA(A1:A5),”Passed”,”Failed”)

    Rumus COUNTIF akan menghitung berapa banyak cell yang berisi “Yes”. Sedangkan Rumus COUNTA akan menghitung berapa banyak cell yang berisi teks.

    Kalo kriteria berupa angka (bukan teks seperti Yes, No dll), ganti COUNTA dengan COUNT.

  37. Mau tanya rumus utk absensi saya di excel, masalahnya :

    jika absen masuk ada dan absen pulang tidak ada maka nilainya “-1”, tapi jika absen masuk tidak ada dan absen pulang tidak ada, maka nilainya “0” dan jika absen masuk ada dan absen pulang ada nilainya “0”.

    Saya minta bantuan di buatkan rumusnya. Terima kasih

  38. Bisa aja dibikin kyk gitu.
    Tapi apa mas yakin kriteria nya udah pas ?
    Ada 2 kriteria yg sama2 menghasilkan “0” loh.
    Terus bagaimana nanti jika ada karyawan yg tidak absen masuk, tapi absen pulang ? Itu belum ada kriterianya.
    Coba lihat pelajari Panduan Fungsi IF+AND di pintasan panduan diatas mas. Konsep nya mirip dengan contoh disana.

  39. mau nanya kak,kalo mau cari jumlah persen pajak dgn cara menghitung selisih wakyu itu bagaimana kak

  40. Hai gan,
    minta bantuan rumusnya jika nilai lebih besar dari 2 maka dikalikan 2%, jika lebih besar dari 5 maka dikalikan 10% dan seterusnya.

    Bagaimana ini dibuat dalam 1 rumus.

    Makasih atas bantuannya.

  41. Kriteria yg paling tinggi di dahulukan.
    Misalnya ada 3 kriteria ii:
    A1 > 10, maka kali 15%
    A1 > 5, maka kali 10%
    A1 > 2, maka kali 2%.
    Pake rumus ini gan:
    IF(A1>10,A1*15%,if(A1>5,A1*10%,if(A1>2,A1*2%,0)))

  42. Bagaimana cara membagi data Tap In Out sesuai jam kerja dan jam istirahat dgn rumus Exel yg terbagi dalam 4 sheet..
    1. Pagi In
    2. Pagi Out
    3. Siang In
    4. Siang Out.

    Terima kasih..

    🙏🙏🙏

  43. Selamat pagi gan.
    Mau tanya
    A2 = 1 agustus 2022, B2 = toko A
    A3 = 1 agustus 2022, B3 = toko B
    A4 = 1 agustus 2022, B4 = toko C
    A5 = 2 agustus 2022, B5 = toko A
    A6 = 2 agustus 2022, B6 = toko D
    ● Jika E2 = tgl 1 agustus 2022
    Maka E3,E4,E5,E6,E7 = toko A, B, C selebihnya kosong.
    ● Jika E8 = tgl 2 agustus 2022
    Maka E9,E10,E11,E12,E13 = toko A,D selebihnya kosong
    Bagaimana rumusnya gan?
    Terima kasih.

  44. Mohon petunjuknya master
    =IFERROR(SUM(IF(P2:P5006=”Ya”;0;2);IF(Q2:Q5006=”Ya”;0;2);IF(R2:R5006=”Ya”;0;2);IF(S2:S5006=”Ya”;0;2);IF(T2:T5006=”Ya”;0;2);IF(U2:U5006=”Ya”;0;2);IF(V2:V5006=”Ya”;0;2))/7;FALSE)
    ketika saya menggunakan rumus ini di excel, rumus ini berfungsi dengan baik (berhasil), tetapi ketika saya pakai di spreadsheet, dengan tambahan fungsi arrayformula tidak berfungsi dengan baik, ketika saya otak atik,malah error. mohon arahan master. sekaligus contoh jadi. terima kasih

  45. Mohon petunjuknya master
    =IFERROR(SUM(IF(P2:P5006=”Ya”;0;2);IF(Q2:Q5006=”Ya”;0;2);IF(R2:R5006=”Ya”;0;2);IF(S2:S5006=”Ya”;0;2);IF(T2:T5006=”Ya”;0;2);IF(U2:U5006=”Ya”;0;2);IF(V2:V5006=”Ya”;0;2))/7;FALSE)
    ketika saya menggunakan rumus ini di excel, rumus ini berfungsi dengan baik (berhasil), tetapi ketika saya pakai di spreadsheet, dengan tambahan fungsi arrayformula tidak berfungsi dengan baik, ketika saya otak atik,malah error. mohon arahan master. sekaligus contoh jadi. terima kasih

    =arrayformula(if(row(A:A)=1;”SKOR KELAYAKAN RUMAH”;ArrayFormula(IFERROR(SUM(IF(P2=”Tidak”;2;0);IF(Q2=”Tidak”;2;0);IF(R2=”Tidak”;2;0);IF(S2=”Tidak”;2;0);IF(T2=”Tidak”;2;0);IF(U2=”Tidak”;2;0);IF(V2=”Tidak”;2;0))/6;””))))

    Rumus yang saya gunakan pada spreadsheet , namun kurang berfungsi dengan baik pada iferror

  46. Tolong bantu dong:
    Nama Tgl lahir usia jenis benefit Periode Peserta Syarat Peserta
    A 17 Mei 1999 23 Pinjaman Renewal Diterima
    B 25 Jan 1925 98 Solduka Addition Ditolak
    C 23 Feb 1998 25 Simpanan Renewal Diterima
    D 13 Mei 1900 132 Pinjaman Renewal Ditolak
    Syarat peserta: Jika Periode peserta adalah Renewal yang diterima adalah jika jenis benefit pinjaman berumur antara 17 tahun – 100 tahun, Simpanan & Solduka yang diterima adalah yang berumur 0 – 100 tahun. Periode peserta Addition, maka yang diterima adalah umur 0-69 tahun. Tolong bantu dong formula if(AND) … nya.. sebelumnya saya ucapkan banyak terima kasih.

Komentar Anda:

Alamat email Anda tidak akan dipublikasikan. Ruas yang wajib ditandai *