Rumus COUNTIF Excel Untuk Menghitung Dengan 1 Kriteria

Apa pengertian Rumus COUNTIF Excel ? Rumus COUNTIF adalah Fungsi yang ada pada Microsoft Excel untuk menghitung berapa banyak data menggunakan kriteria / syarat / kondisi yang dapat Anda tentukan sendiri.

Note: Jika Anda ingin menjumlahkan data (berupa Angka) dalam File Excel, silahkan gunakan Rumus SUMIF atau SUMIFS. Kunjungi Panduan SUMIF dan SUMIFS Excel. (Lihat Pintasan Panduan di Akhir halaman ini)

Pada panduan ini Anda akan belajar bagaimana cara menggunakan Rumus / Fungsi COUNTIF. Contoh Saya susun berbasarkan berbagai kondisi yang mudah dipahami.

Penting! Pastikan Anda sudah mengerti cara memasukkan Fungsi / Rumus Excel baik itu menggunakan tanda sama dengan (=) atau menggunakan fitur Insert Function.

Jika Anda belum tahu, silahkan kunjungi Panduan Rumus VS Fungsi Excel

Aturan Penulisan Rumus COUNTIF Excel

Sebelum menggunakan Rumus / Fungsi COUNTIF, penting untuk Anda ketahui aturan penulisan Rumus COUNTIF Excel.

Sama seperti fungsi lainnya, fungsi COUNTIF juga memiliki aturan penulisan. Secara default, aturan Fungsi COUNTIF sebagai berikut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(range,criteria)

Artinya:
Hitung Banyak Data Jika range merupakan criteria

Lihat, ada 2 argument utama dalam Fungsi COUNTIF ini sebagai berikut:

  1. range: merupakan sekelompok cell yang akan Anda hitung jumlah datanya. Jika Anda belum tahu apa itu Range, silahkan kunjungi Panduan Range, Cell, Column dan Row M Jurnal
  2. criteria: merupakan kriteria / syarat / kondisi yang Anda tentukan. Atau bisa juga disebut sebagai syarat data yang akan dihitung jumlahnya.

Dengan kata lain, Excel akan menghitung jumlah data / banyaknya data pada Range berdasarkan kriteria yang Anda tentukan.

Misalnya, pada Range A1:A5 berisi data (berturut-turut) AA, BB, CC, AA, CD. Jika Anda menggunakan Rumus / Fungsi COUNTIF berikut: =COUNTIF(A1:A5,”AA”), maka Excel akan memberikan hasil 2

Kenapa ? karena kriteria pada Rumus COUNTIF Excel tersebut adalah AA. Maka Excel akan menghitung berapa banyak jumlah Cell pada Range A1:A5 yang berisi AA.

Note: tanda koma dalam rumus ” =COUNTIF(A1:A5,“AA”) ” merupakan Operator Pemisah Rumus. Tidak semua Aplikasi Excel menggunakan tanda koma (,), ada juga yang menggunakan tanda titik koma (;). Ini tergantung pengaturan Regional Komputer Anda.

Anda bisa pelajari tentang operator pemisah rumus pada Panduan Union & Intersect Excel

Tapi bukan itu saja cara menggunakan dan makna Fungsi COUNTIF. Anda akan menemukan pandangan lain tentang Fungsi COUNTIF dari beberapa contoh di bawah.

Contoh Rumus COUNTIF Excel Online

Sebagai bahan latihan, Silahakan download atau gunakan file Excel Online berikut:

Note:
1. Silahkan klik Icon Full Screen Pada Sudut Kanan Bawah File Excel Online berikut untuk menggunakan fitur Excel Online.
2. Klik Icon Download (gambar selembar kertas dengan tanda panah kebawah) pada baris sudut kanan bawah File Excel Online berikut untuk download file.
3. Jika Link Download atau Excel Online Error, silahkan beritahu Saya melalui kolom komentar (Terima kasih 🙂 ).

Rumus COUNTIF Dengan Kriteria Angka

Ada banyak cara menggunakan Rumus COUNTIF Excel dengan kriteria berupa angka.

Dalam panduan ini sudah Saya rangkum beberapa contoh kasus yang sering terjadi. Silahkan Buka Sheet COUNTIF NUMERIC pada Excel Online yang sudah Saya berikan.

COUNTIF dengan Kriteria Angka Manual

Saya memiliki data daftar nilai pada kolom B dan C. Saya ingin menghitung berapa banyak Siswa yang memiliki Nilai 75. Ingat, daftar nilai berada pada kolom C yaitu Range C2:C10. Hasilnya akan Saya tampilkan pada Cell C12.

Range data sudah kita ketahui serta kriteria COUNTIF sudah ada. Maka silahkan ikuti tahap-tahap berikut:

Rumus COUNTIF Excel kriteria Angka
  1. Pertama, masukkan Fungsi COUNTIF pada Cell C12 seperti berikut: =COUNTIF(
  2. Kedua, blok range data yaitu C2:C10 kemudian ketik operator pemisah rumus ( , atau ; ). Sehingga Fungsi COUNTIF menjadi =COUNTIF(C2:C10,
  3. Ketiga, ketik angka 75 sebagai kriteria. Kemudian ketik tanda tutup kurung ) dan tekan enter. Berikut hasilnya:
Cara menghitung banyak data menggunakan fungsi excel

Excel memberikan hasil 3. Secara kasat mata, memang benar nilai 75 pada range C2:C10 terdapat pada 3 cell yaitu C2, C4 dan C7. Lalu apa makna Fungsi COUNTIF tersebut ?

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,75)

Artinya:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan 75

Excel akan mengabaikan cell yang berisi selain 75.

COUNTIF dengan Kriteria Cell Reference

Maksud dari Kriteria Cell Reference adalah kriteria Rumus COUNTIF yang terdapat pada Cell lain (bisa dalam sheet yang sama maupun sheet berbeda).

Jadi dalam contoh ini Saya akan menghitung berapa banyak jumlah cell yang berisi 82.

Masih menggunakan contoh yang sama. Namun ada informasi tambahan bahwa kriteria terdapat pada Cell D13 yaitu berisi nilai 82 dan hasilnya akan Saya tunjukan pada Cell C13. Silahkan ikuti tahap-tahap berikut:

Rumus COUNTIF Excel kriteria Angka dengan Cell Reference
  1. Pertama, ketik fungsi COUNTIF pada Cell C13 dan blok Range data kemudian ketik operator pemisah rumus ( , atau ; ) seperti berikut: =COUNTIF(C2:C10,
  2. Kedua, klik Cell D13 sebagai kriteria pada rumus.
  3. Ketiga, ketik tanda tutup kurung kemudian tekan Enter. Berikut hasilnya:
Cara menghitung data berdasarkan kriteria pada excel

Excel memberikan hasil 2 yaitu Cell C3 dan C8. Berikut makna Fungsi COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,D13)

Tulis Rumus / Fungsi COUNTIF:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan Cell D13

Jadi, Cell D13 menjadi kunci pada contoh ini. Jika Anda merubah nilai pada Cell D13 menjadi 100, Excel akan memberikan hasil 0. Karena pada Range data tidak terdapat Cell yang berisi nilai = 100 seperti gambar berikut:

Cara menghitung data berdasarkan kriteria pada excel

COUNTIF dengan Kriteria Berupa Operator Perbandingan Rumus + Manual

Dalam Excel, operator perbandingan rumus sangat berguna untuk uji logika. FYI, Operator Perbandingan Rumus ini berupa tanda lebih dari (>), Kurang dari (<), sama dengan (=), tidak sama dengan (<>) dll.

Note: Jika Anda belum tahu apa saja operator perbandingan pada Excel serta cara menggunakannya, Silahkan Kunjungi Panduan Operator Perbandingan Rumus Excel

Masih menggunakan Sheet yang sama. Saya ingin menghitung berapa banyak Cell yang berisi angka lebih besar atau sama dengan 75 (>=75). Hasilnya akan Saya tunjukkan pada Cell C14.

Kita menggunakan Operator Perbandingan Rumus >=. Silahkan ikuti tahap-tahap berikut:

Cara menggunakan Rumus COUNTIF untuk menghitung data berdasarkan kriteria - Uji logika
  1. Pertama, ketik Fungsi COUNTIF dan Blok Range data kemudian ketik operator pemisah rumus ( , atau ; ) seperti berikut: =COUNTIF(C2:C10,
  2. Kedua, ketik “>=75”) kemudian tekan Enter. Berikut hasilnya:

Note: Jika kriteria berupa Angka, maka Anda tidak perlu mengapitnya dengan tanda kutip dua ” “. Sementara kriteria pada contoh ini menggunakan gabungan operator perbandingan dan angka, maka harus diapit tanda kutip 2 ” “.

Cara menghitung data berdasarkan kriteria pada excel

Excel memberikan hasil 7 yaitu data pada Cell C2, C3, C4, C6, C7, C8 dan C10. Sementara makna Fungsi COUNTIF tersebut sebagai berikut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,“>=75”)

Artinya:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan Lebih Besar dari 75

Contoh lainnya, Saya ingin menghitung berapa banyak data yang tidak berisi nilai 75 pada Range C2:C10.

Untuk contoh ini, silahkan masukkan Fungsi COUNTIF berikut: =COUNTIF(C2:C10,”<>75″) pada cel C15. Dan berikut hasilnya:

Cara menghitung data berdasarkan kriteria pada excel

Excel memberikan hasil 6 yaitu Cell C3, C5, C6, C8 dan C10. Berikut makna Fungsi COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,“<>75”)

Artinya:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan Tidak Sama Dengan 75

Butuh Contoh lainnya ? lihat beberapa contoh berikut:

COUNTIF dengan Kriteria Berupa Operator Perbandingan Rumus + Cell Reference

Sesuai judulnya, Kriteria Rumus COUNTIF Excel pada contoh ini menggunakan Operator Perbandingan Rumus dan Cell Reference.

Saya masih menggunakan contoh pada Sheet yang sama. Saya ingin menghitung berapa banyak cell yang memiliki nilai kurang dari nilai pada Cell D16.

Cell D16 ini berisi angka 75. Anda bisa mengubahnya sesuai kebutuhan. Untuk contoh seperti ini, silahkan ikuti tahap-tahap berikut:

Cara menggunakan rumus countif untuk menghitung banyak data berdasarkan kriteria
  1. Pertama, masukkan Rumus COUNTIF, blok range data dan ketik operator pemisah rumus ( , atau ; ) seperti berikut: =COUNTIF(C2:C10, pada Cell C16
  2. Kedua, ketik Operator Pemisah Rumus (apit dengan tanda kutip 2) seperti berikut “<=” kemudian ketik & sehingga rumus COUNTIF menjadi =COUNTIF(C2:C10,”<=”&
  3. Ketiga, klik Cell D16 kemudian ketik tanda tutup kurung dan tekan Enter. Berikut hasilnya:
Cara menghitung data berdasarkan kriteria pada excel

Excel memberikan hasil 5 yaitu Cell yang memiliki nilai lebih kecil dari atau sama dengan nilai pada Cell D16 yaitu 75. Anda Wajib Tahu Makna Fungsi =COUNTIF(C2:C10,”<=”&D16) tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,“<=”&D16)

Tulis Rumus / Fungsi COUNTIF:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan Lebih Kecil Dari atau Sama Dengan Cell D16

Tanda “<=” merupakan operator perbandingan rumus. Tanda & dalam rumus Excel berguna untuk menggabungkan operator pemisah rumus dan Reference Cell. Sementara D16 adalah reference Cell.

Excel mengartikan Argument “<=”&D16 sebagai <=D16. Tapi, Anda tidak bisa ketik seperti ini: <=D16 ataupun seperti ini “<=D16. Ikuti aturan penulisan rumus nya.

COUNTIF Ganda Dengan 2 Kriteria

Contoh ini sebenarnya sebuah trik jika Anda ingin mengetahui berapa banyak cell yang memiliki data sesuai 2 kriteria untuk Range data yang sama. Biar lebih paham, silahkan simak contoh berikut:

Saya masih menggunakan contoh yang sama dengan sebelumnya. Perbedaannya, Saya menggunakan 2 kriteria. Yaitu Saya ingin menghitung berapa banyak Cell yang berisi angka 75 dan 82 pada Range C2:C10.

Ingat, Range data hanya ada 1 yaitu C2:C10. Sementara kriteria ada 2 yaitu 75 dan 82. Untuk contoh ini, Anda bisa menggunakan COUNTIF ganda dan operator rumus penjumlahan (+) seperti berikut:

Cara menggunakan rumus COUNTIF berganda pada Excel
  1. Pertama, masukkan Rumus COUNTIF pada Cell C17, blok range data dan ketik operator pemisah rumus ( , atau ; ) seperti berikut: =COUNTIF(C2:C10,
  2. Kedua, ketik 75 sebagai kriteria pertama kemudian ketik tanda tutup kurung )
  3. Ketiga, ketik tanda tambah + sehingga Rumus COUNTIF menjadi =COUNTIF(C2:C10,75)+
  4. Terakhir, ulangi tahap 1 sampai 3 (tanpa tanda sama dengan “=”). Dan ubah Kriteria dari 75 menjadi 82, sehingga Rumus menjadi =COUNTIF(C2:C10,75)+COUNTIF(C2:C10,82) kemudian tekan enter dan berikut hasilnya:
Cara menghitung data berdasarkan kriteria pada Excel

Excel memberikan hasil 5 yaitu jumlah cell yang memiliki nilai sama dengan 75 dan 82. Berikut penjelasan Fungsi COUNTIF Ganda tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C2:C10,75)+COUNTIF(C2:C10,82)

Artinya:
Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan 75 Ditambah Hitung Banyak Data Jika Cell C2 sampai Cell C10 merupakan 82

Pertama-tama, Excel akan menghitung banyak cell yang terdapat angka 75 yaitu ada 3 Cell (C2, C4, dan C7). Kemudian menghitung banyak cell yang terdapat angka 82 yaitu ada 2 cell (C3 dan C8). Terakhir menjumlahkannya yaitu 3+2 = 5

Penting! Jika Anda ingin menghitung banyak data menggunakan 2 atau lebih kriteria yang berbeda maupun sama, silahkan gunakan Rumus COUNTIFS. Lihat pintasan Panduan di akhir artikel ini.

Rumus COUNTIF Dengan Kriteria Teks

Contoh ini sangat cocok jika kriteria yang Anda inginkan berupa teks atau campuran Teks dan Angka atau teks dan karakter lainnya atau berupa Pesan Error dari Excel seperti #N/A atau #VALUE! atau #REF! dll.

Penting! Jika kriteria Anda berupa TRUE dan FALSE yang merupakan hasil dari sebuah rumus (seperti AND, OR dll) ataau ketik manual, maka Anda tidak bisa menggunakan contoh ini.

Untuk TRUE atau FALSE Saya bahas pada bagian Rumus COUNTIF Excel Untuk TRUE dan FALSE dibawah.

Sekarang kita fokus terlebih dahulu dengan rumus COUNTIF untuk kriteria berupa teks. Setidaknya ada 7 trik menggunakan rumus COUNTIF untuk kriteria berupa Teks sebagai berikut:

COUNTIF dengan Kriteria Teks Murni

Saya sebut kriteria teks murni karena kriteria dalam rumus COUNTIF hanya berupa teks saja.

Emang ada yang ga murni ? Ada, misalnya menggunakan tanda tanya (?) atau tanda bintang (*). Anda akan melihat caranya setelah contoh ini.

Untuk Rumus COUNTIF dengan kriteria teks murni, silahkan buka Sheet COUNTIF TEXT pada File Excel Online yang Saya berikan sebelumnya.

Kolom C berisi data campur, ada Teks, Angka dan Gabungan. Untuk contoh Kriteria Teks Murni, Saya ingin menghitung cell yang berisi Buku pada Range C1:C10. Hasilnya akan Saya tampilkan pada Cell C12.

Anda masih ingat cara memasukkan Rumus COUNTIF Dengan Kriteria Berupa Angka Manual di atas ? Jika lupa silahkan kembali keatas.

Karena Kriteria dan Range sudah kita ketahui, maka ketik Fungsi COUNTIF berikut: =COUNTIF(C1:C10,”Buku”) pada Cell C12 seperti cara sebelumnya kemudian tekan enter, berikut hasilnya:

Note: Perbedaan terdapat pada kriteria, karena kriteria contoh ini berupa teks (bukan angka), maka Anda perlu mengapitnya dengan tanda kutip dua ” “.

Rumus COUNTIF dengan kriteria berupa teks

Anda bisa lihat, Excel memberikan hasil 2 yaitu Cell C1 dan C10 berisi Buku.

Loh kenapa Cell C10 termasuk ? padahal Cell C10 berisi BUKU (dengan huruf kapital).

Nah, dari situ Anda bisa tahu. Bahwa Rumus COUNTIF tidak mempertimbangkan huruf kapital atau tidak. Bahasa teknis nya Case Sensitive. Excel hanya menghitung jumlah karater yang sama dengan kriteria. Berikut Saya jelaskan makna Fungsi COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C1:C10,“Buku”)

Tulis Rumus / Fungsi COUNTIF:
Hitung Banyak Data Jika Cell C1 sampai Cell C10 merupakan Buku

COUNTIF dengan Kriteria Teks + ?

Sesuai judulnya, Kita akan menggabungkan kriteria berupa teks dengan tanda tanya ( ? ). Contoh ini bisa Anda gunakan untuk menghitung banyak data dengan kriteria yang beragam.

Satu buah Tanda Tanya ( ? ) dapat mewakili 1 karakter apapun. Bisa huruf A, B, sampai Z, atau angka 1, 2, dst.. Bisa juga berupa karakter seperti tanda tambah, minus, titik dll. Biar semakin paham, Silahkan simak contoh berikut:

Masih menggunakan contoh yang sama (Sheet COUNTIF TEXT). Coba Anda lihat data pada Range C1:C10. Ada banyak macam kata Buku di setiap cell. Ada Buku, Buku1, Buku Tulis, Buku+, Pena dan Buku, BUKU dan ada juga Buku2 dengan spasi diawalnya (Cell C5).

Saya ingin menghitung berapa banyak cell yang berisi Buku dengan 1 karakter terakhir (apapun) di belakangnya. Silahkan masukkan Fungsi COUNTIF berikut: =COUNTIF(C1:C10,”Buku?”) pada Cell C13 dan tekan enter. Berikut hasilnya:

Cara menggunakan rumus COUNTIF untuk kriteria Teks dan tanda tanya ?

Anda bisa liat, Excel memberikan hasil 2 yaitu Cell C4 dan C8 yang berisi Buku + 1 karakter apapun. Lalu apa makna Fungsi COUNTIF tersebut ?

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C1:C10,“Buku?”)

Artinya:
Hitung Banyak Data Jika Cell C1 sampai Cell C10 merupakan Buku + 1 karakter apapun setelahnya

Kenapa Cell C5 tidak termasuk ? Karena ada spasi di awal kata Buku2. Sementara kriteria di awali dengan kata Buku dan diakhiri dengan 1 karakter apapun (?).

Kenapa Cell C7 tidak termasuk, padahal ada karakter lain setelah kata buku ? karena jumlah karakter lain sesudah kata buku lebih dari 1 yaitu ada 1 spasi kemudian 5 huruf (tulis).

Saya beri contoh, coba Anda ketik rumus berikut: =COUNTIF(C1:C10,”Buku??????”) pada cell C14. Excel akan memberikan hasil 1 seperti gambar berikut:

Note: Jumlah Tanda tanya ada 6.

Cara menghitung banyak data dengan kriteria berupa teks dan tanda tanya ? pada excel

Benar bukan ? Jumlah tanda tanya pada kriteria ada 6. Sehingga Excel memberikan hasil 1 yaitu Cell C7 berisi Buku Tulis.

COUNTIF dengan Kriteria Teks + * ?

Dalam Excel, Tanda Bintang * dapat mewakili karakter apapun dalam jumlah berapapun.

Kegunaannya kurang lebih sama dengan tanda tanya. Perbedaannya, satu tanda bintang * dapat mewakil berapa banyak pun karakter setelahnya, Serta tanda bintang ini merupakan optional.

Dengan kata lain, jika Anda menggunakan kriteria Buku*, maka Excel akan menghitung cell yang berisi Buku dan Buku dengan karakter apapun dan berapapun setelahnya.

Misalnya, dengan contoh yang sama Saya ingin menghitung berapa banyak Cell yang berisi kata Buku dengan berapapun jumlah karakter setelahnya. Jadi Buku, Buku1, Buku Tulis dan Buku+ juga akan termasuk.

Silahkan ketik rumus COUNTIF berikut =COUNTIF(C1:C10,”Buku*”) pada Cell C15 dan berikut hasilnya:

Cara menggunakan Rumus COUNTIF dengan kriteria berupa teks dan tanda bintang * pada Excel

Benar kan ? Excel memberikan hasil 5 yaitu Cell C1=Buku, C4=Buku1, C7=Buku Tulis, C8=Buku+ dan C10=BUKU. Berikut makna dari Rumus COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C1:C10,“Buku*”)

Artinya:
Hitung Banyak Data Jika Cell C1 sampai Cell C10 merupakan Buku atau Buku + 1 karakter apapun setelahnya

Bagaimana ? Mudah kan memahaminya ? Saya punya contoh lagi nih tentang tanda bintang.

COUNTIF dengan Kriteria *

Pada Contoh ini, Saya hanya menggunakan tanda bintang saja tanpa teks atau yang lainnya. Silahkan masukkan Rumus berikut: =COUNTIF(C1:C10,”*”) pada Cell C16 berikut hasilnya:

Ingat! tanda bintang bukanlah angka, maka harus di apit dengan tanda kutip 2.

Rumus COUNTIF dengan kriteria *

Excel memberikan hasil 8. Ternyata Excel mengabaikan Cell yang berisi Angka yaitu Cell C3 dan C6. Berikut makna Fungsi COUNTIF yang digunakan:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C1:C10,“*”)

Artinya:
Hitung Banyak Data Jika Cell C1 sampai C10 merupakan Karakter Apapun

Cell C3 berisi angka 10. Coba Anda ubah menjadi karakter apapun selain angka. Misalnya Saya ubah menjadi Penghapus. Silahkan lihat hasil rumus pada Cell C16 akan berubah menjadi 9. Seperti gambar berikut:

cara menghitung banyak data dengan kriteria tanda * pada excel

Kenapa ? karena secara default jika kriteria rumus COUNTIF tidak menggunakan angka, maka Excel akan mengabaikan cell yang berisi Angka saja.

Makanya di awal panduan ini Saya tulis Rumus COUNTIF dengan kriteria berupa angka. 🙂

COUNTIF dengan Kriteria * + Teks + *

Tanda bintang juga bisa Anda sisipikan di awal dan di akhir teks kriteria. Misalnya, coba ketik rumus berikut: =COUNTIF(C1:C10,”*Buku*”) pada cell C17. Berikut hasilnya:

Rumus COUNTIF dengan kriteria berupa teks dan tanda bintang * pada Excel

Excel memberikan hasil 7 yaitu cell C2, C4, C5, C7, C8, C9 dan C10. Berikut penjelasan makna Fungsi COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(C1:C10,“*Buku*”)

Artinya:
Hitung Banyak Data Jika Cell C1 sampai Cell C10 merupakan karakter apapun+Buku atau Buku atau Buku+karakter apapun

COUNTIF dengan Kriteria Pesan Error Excel

Langsung ke contoh aja. Silahkan lihat Kolom H dan I pada Sheet COUNTIF TEXT. Terdapat beberapa cell yang berisi pesan kesalahan Excel (#REF! dan #VALUE!).

Tujuan Saya, ingin menghitung berapa banyak cell yang berisi pesan Error #REF! pada Range H1:I8. Untuk itu silahkan ketik Rumus berikut: =COUNTIF(H1:I8,”#REF!”) pada cell I11. Hasilnya akan seperti gambar berikut:

Note: Saya menggunakan Range H1:I8 artinya Saya menggunakan range data untuk 2 kolom (Kolom H dan I). Anda juga bisa menggunakan cara ini untuk contoh Rumus COUNTIF yang lainnya jika diperlukan.

Rumus COUNTIF untuk menghitung pesan error excel #REF!

Excel memberikan hasil 6 yaitu Cell H1, H6, H8, I4, I6, dan I8. Sedangkan makna Fungsi COUNTIF tersebut adalah:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(H1:I8,“#REF!”)

Artinya:
Hitung Banyak Data Jika Cell H1 sampai Cell I8 merupakan #REF!)

Fungsi COUNTIF diatas hanya menghitung jumlah cell yang berisi pesan Error #REF! saja. Lalu bagaimana cara menghitung semua pesan Error Excel dalam 1 Range data ?

Saya Punya Triknya 😀

Trik: Array Formula – Kombinasi Fungsi COUNT, IF dan ISERROR

Trik ini menggunakan gabungan fungsi COUNT, IF, dan ISERROR. Caranya silahkan ikuti tahap-tahap berikut:

Kombinasi Rumus COUNT, IF, dan ISERROR untuk menghitung berapa banyak cell yang berisi pesan error Excel #REF! , #VALUE!
  1. Pertama, masukkan fungsi COUNT seperti berikut: =COUNT( pada cell H12
  2. Kedua, masukkan fungsi IF sehingga rumus menjadi =COUNT(IF(
  3. Ketiga, masukkan fungsi ISERROR sehingga rumus menjadi =COUNT(IF(ISERROR(
  4. Keempat, blok range data H1:I8 kemudian ketik tanda tutup kurung ) untuk menutup fungsi ISERROR dan ketik operator pemisah rumus ( , atau ; )
  5. Kelima, ketik angka 1 kemudian ketik operator pemisah rumus ( , atau ; ). Angka 1 merupakan argument value_if_true pada rumus IF.
  6. Keenam, ketik tanda kutip 2 sebanyak 2x seperti ini “” sehingga rumus menjadi =COUNT(IF(ISERROR(H1:I8),1,””
  7. Ketujuh, ketik tanda tutup kurung untuk fungsi IF dan tanda tutup kurung untuk fungsi COUNT. Note: Tanda tutup kurung nya 2x
  8. Terakhir, tekan tombol CTRL, SHIFT, dan ENTER pada Keyboard secra bersamaan. Berikut hasilnya:
Kombinasi Rumus COUNT, IF, dan ISERROR dengan ARRAY FORMULA EXCEL

Jangan lupa tekan tombol CTRL SHIFT dan ENTER secara bersamaan. Jika tidak, Excel hanya akan memberikan hasil 1. Sementara, hasil sebenarnya adalah 9 seperti gambar di atas.

Note: Setelah Anda tekan CTRL SHIFT dan ENTER bersamaan, Excel akan mengapit rumus dengan tanda kurung kurawal (seperti gambar). Jangan ketik kurung kurawal secara manual. Biarkan Excel yang melakukannya.

Makna Gabungan Fungsi tersebut sebagai berikut:

Tulis Rumus / Fungsi Gabungan:
{=COUNT(IF(ISERROR(H1:I8),1,“”))}

Artinya:
Hitung Banyak Data dengan Syarat Jika data Adalah Error pada Cell H1 sampai Cell I8 maka 1 selain dari itu Abaikan

Dengan kata lain, langkah-langkah Excel mengartikan gabungan Fungsi tersebut sebagai berikut:

  1. Excel akan melakukan pengecekan data apakah terdapat Error pada Range H1:I8. Ini Tugas Fungsi ISERROR.
  2. Kemudian setiap cell yang berisi pesan error, akan dianggap 1. Ini Tugas Fungsi IF.
  3. Jika cell tidak berisi pesan error, maka cell tersebut dianggap kosong. Ini juga tugas Fungsi IF.
  4. Terakhir, Excel akan menghitung jumlah semua angka 1 yang dihasilkan Fungsi IF. Ini tugas Fungsi COUNT.

Note: Jika Anda belum tahu cara menggunakan Fungsi IF, silahkan kunjungi Panduan Fungsi IF M Jurnal.

Rumus COUNTIF Untuk TRUE dan FALSE

Seperti yang Saya sebutkan sebelumnya, beberapa Rumus Logical pada Excel akan memberikan hasil TRUE dan FALSE seperti rumus AND, OR dll.

Untuk contoh Rumus COUNTIF TRUE dan FALSE, silahkan buka Sheet COUNTIF TRUE FALSE pada Excel Online yang Saya berikan sebelumnya.

Data Tersusun pada Kolom B, C, D, dan E. Pada Kolom E (Hasil), Saya menggunakan Fungsi OR sehingga Excel memberikan hasil TRUE atau FALSE.

Dengan kondisi seperti ini, Saya ingin menghitung berapa banyak jumlah TRUE dan menampilkan hasilnya pada Cell E10. Saya juga akan menghitung banyak FALSE dan menampilkannya pada Cell E11.

Silahkan ketik Rumus berikut: =COUNTIF(E2:E6,TRUE) pada Cell E10 dan rumus berikut =COUNTIF(E2:E6,FALSE) pada Cell E10. Berikut hasilnya:

Note: Anda tidak perlu mengapit kriteria TRUE atau FALSE dengan tanda kutip 2. Meskipun TRUE dan FALSE merupakan hasil dari ketik manual (bukan rumus).

Rumus COUNTIF untuk menghitung banyak cell yang terdapat TRUE dan FALSE

Mudah bukan ? Excel memberikan hasil 2 untuk TRUE dan 3 untuk FALSE. Terakhir yang ingin Saya berikan kepada Anda, makna dari Fungsi COUNTIF tersebut:

Tulis Rumus / Fungsi COUNTIF:
=COUNTIF(E2:E6,TRUE)
Atau
=COUNTIF(E2:E6,FALSE)

Artinya:
Hitung Banyak Data Jika Cell E2 sampai Cell E6 merupakan TRUE
Atau
Hitung Banyak Data Jika Cell E2 sampai Cell E6 merupakan FALSE

Pintasan Panduan COUNT & SUM Excel

  1. COUNT & SUM: Jenis-jenis dan cara menggunakan Fungsi Count dan SUM di Excel (COUNT, COUNTIF, COUNTIFS, SUM, SUMIF, SUMIFS)
  2. COUNT Blank/Non-Blank Cells: Fungsi untuk menghitung jumlah Cell kosong dan yang berisi.
  3. COUNTIF: (Anda Disini)
  4. COUNTIFS: Cara menggunakan Fungsi COUNTIFS untuk menghitung banyak data dengan 2 atau lebih kriteria.
  5. COUNT Characters: Cara menghitung jumlah karakter dalam Cell atau Range dan cara menghitung berapa kali karakter tertentu muncul dalam Cell atau Range.
  6. COUNT Cells with Text: Fungsi untuk menghitung jumlah Cell yang berisi huruf
  7. SUM: Fungsi SUM Lengkap (seperti menjumlahkan Range tertentu, semua kolom, cell yang berjauhan, angka besar, menjumlahkan otomatis, menjumlahkan setiap baris ke-n, dll)
  8. Running Total: Menjumlahkan total berjalan (Total berjalan akan berubah setiap nilai baru di tambahkan)
  9. SUMIF: Cara menggunakan Fungsi SUMIF untuk menjumlahkan dengan syarat (Lengkap)
  10. SUMIFS: Cara Menggunakan Fungsi SUMIFS untuk menjumlahkan data dengan banyak Syarat / kriteria.
  11. SUMPRODUCT: Cara menjumlahkan yang lebih kompleks (pahami setiap contohnya)

R_Mardani

"Write based on Experience"

Komentar Paling Lambat di Balas Pukul 23:59 :)