3 Cara Menggunakan Konstanta Pada Rumus ARRAY Excel

Konstanta Rumus ARRAY – Setiap Rumus / Fungsi memiliki argument tersendiri yang bisa terdiri dari sebuah data yang diketik secara manual (konstanta), cell, range, named range, struktur tabel, dan operator.

Secara sederhana, konstanta bisa berupa sebuah nilai yang diketik secara manual ke dalam Rumus / Fungsi Excel. Jika Konstanta berupa angka, cell atau range, maka Anda bisa langsung mengetiknya. Dan jika berupa teks, maka Anda harus mengapitnya dengan kutip 2 ” “.

Misalnya seperti Rumus =A1+5 atau =IF(A1>=75,"Lulus","Gagal"). Angka 5 pada Rumus pertama dan angka 75, teks “Lulus” dan “Gagal” pada Rumus kedua disebut juga dengan konstanta pada Rumus.

Sementara itu, Anda hanya bisa menggunakan 1 data sebagai konstanta pada argument rumus biasa. Sedangkan pada Rumus ARRAY, Anda bisa menggunakan lebih dari 1 data. Misalnya, {=A1+{5;2;7;9}}. Argument {5;2;7;9} terdiri lebih dari 1 data bukan ?

Note: Menulis Konstanta pada Rumus ARRAY tidak sama dengan Rumus Biasa. Biar semakin paham, coba dalami dahulu bagian Tombol F9 berikut:

Tombol F9: Lihat Konstanta Rumus ARRAY Excel

Penting! Sebelum melanjutkan, perhatikan bahwa menulis konstanta pada Rumus ARRAY untuk format Indonesia dan English tidak sama. Software Excel Saya menggunakan Format English. Ada baiknya sesuaikan format Excel Anda dengan Saya. Untuk mengubah Format, silahkan ikuti Panduan Format English vs Indonesia

Ketika menggunakan Rumus ARRAY, sebagian besar pengguna lebih sering menggunakan Range sebagai reference. Namun, selain menggunakan Range, Anda juga bisa menggunakan Konstanta Array. Misalnya seperti Rumus ARRAY berikut:

Cell A₈ menggunakan Rumus {=SUM(E2:E6*F2:F6)}. Sekarang coba edit rumus melalui formula bar dan pilih (blok) F₂:F₆ didalam argument rumus. Kemudian tekan tombol F9 pada Keyboard dan akhiri dengan menekan Ctrl + Shift + Enter secara bersamaan.

Excel akan mengubah Range tersebut menjadi Konstanta seperti berikut: {=SUM(E2:E6*{1;2;3;4;5})}. Inilah yang disebut dengan Konstanta pada Rumus ARRAY.

Lihat, Konstanta {1;2;3;4;5} diambil dari Range data (F₂:F₆) secara berurutan. Sehingga, jika data pada Kolom F tidak ada, serta Saya menggunakan Rumus {=SUM(E2:E6*{1;2;3;4;5})} pada Cell E₉, maka Saya juga akan mendapatkan hasil sesuai tujuan:

Dengan kata lain, Anda juga bisa menggunakan Konstanta ARRAY sebagai pengganti Range data di dalam Rumus.

Namun, cara memasukkan Konstanta untuk ARRAY 1 dimensi baik vertikal maupun horizontal dan ARRAY 2 dimensi tidak sama. Ada aturan khusus yang perlu Anda ketahui.

Mari kita pelajari satu per satu.

#1 Konstanta ARRAY 1 Dimensi Vertikal

Dalam Rumus ARRAY, Anda juga bisa memasukkan konstanta ke setiap baris dari Range data dengan cara berikut:

1. Pilih (blok) range data 1 dimensi vertikal. Dalam contoh ini Range A₁:A₅
2. Ketik tanda sama dengan untuk mengawali rumus.
3. Ketik tanda buka kurung kurawal {
4. Masukkan konstanta Anda (harus sebanyak cell yang Anda pilih / blok) dan pisahkan setiap konstanta dengan tanda titik koma (;). Dalam contoh ini 1;2;3;4;5
5. Ketik tanda tutup kurung kurawal }
6. Tekan tombol Ctrl + Shift + Enter pada Keyboard secara bersamaan. Dan lihat hasilnya:

Benar bukan ? Sekarang semua konstanta dimasukkan ke dalam setiap baris dari range data yang terpilih.

Note: Untuk format Indonesia, Anda juga bisa menggunakan titik koma (;) sebagai pemisah konstanta {={1;2;3;4;5}}

Selain itu, Anda harus mengetik kurung kurawal yang mengapit konstanta {1;2;3;4;5} secara manual.

Berbeda dengan kurung kurawal yang mengapit rumus ARRAY {={1;2;3;4;5}}. Kurung kurawal tersebut otomatis muncul setelah Anda menekan Ctrl + Shift + Enter.

Nah itulah cara kerja paling sederhana dari konstanta pada Rumus ARRAY (juga berlaku untuk contoh berikutnya: 1 dimensi horizontal dan 2 dimensi).

Sekarang Saya masuk ke contoh soal. Saya memiliki data pada Cell C₁:C₅ seperti berikut:

Kemudian, Saya ingin mengali nilai setiap cell seperti berikut: C₁*1, C₂*2, C₃*3, C₄*4 dan C₅*5 tanpa menambahkan data 1, 2, 3, 4, dan 5 ke dalam sheet.

Untuk tujuan tersebut, Anda bisa menggunakan bantuan Konstanta Rumus ARRAY. Silahkan gunakan Rumus berikut: =C1:C5*{1;2;3;4;5} kemudian tekan Ctrl + Shift + Enter secara bersamaan. Lihat hasilnya:

Note: Kurung kurawal yang mengapit konstanta harus diketik secara manual.

Benar bukan ?

Itu contoh untuk Rumus ARRAY Multi Cell. Sementara, Anda juga bisa menggunakannya untuk ARRAY Cell Tunggal. Misalnya Saya menggunakan Rumus berikut: =SUM(C1:C5*{1;2;3;4;5}), kemudian tekan Ctrl + Shift + Enter.

Rumus ini jauh lebih cepat daripada Anda menggunakan ARRAY Multi Cell kemudian menggunakan Fungsi SUM untuk menjumlahkannya.

#2 Konstanta ARRAY 1 Dimensi Horizontal

Konstanta ARRAY 1 Dimensi Vertikal menggunakan titik koma (;) sebagai pemisah setiap konstanta, baik itu pada Software Excel dengan Format English maupun Indonesia. Sementara itu, berbeda pada Konstanta ARRAY 1 Dimensi Horizontal.

Jika Software Excel Anda menggunakan Format English, maka gunakan tanda koma (,). Sedangkan jika menggunakan format Indonesia, maka gunakan backslash (\) sebagai pemisah setiap konstanta.

Misalnya, gunakan rumus berikut pada Range A₁:E₁ ={1,2,3,4,5} untuk format English atau ={1\2\3\4\5} untuk format Indonesia. Anda akan mendapatkan hasil seperti berikut:

Perbedaannya hanya pemisah setiap konstanta saja. Sementara itu, tanda kurung kurawal yang mengapit konstanta wajib di ketik secara manual. Selanjutnya tekan Ctrl + Shift + Enter secar bersamaan. Hanya sesederhana itu saja.

Lalu bagaimana cara menggunakannya Konstanta ini ke dalam Rumus ARRAY ?

Sama seperti contoh sebelumnya, namun yang perlu diperhatikan, sumber data (range yang sudah ada) harus terdiri dari 1 dimensi horizontal juga.

Range A₅:E₅ menggunakan Rumus {=A3:E3*{1,2,3,4,5}}, ini contoh yang benar. Sedangkan contoh yang salah pada Range A₆:E₆ menggunakan Rumus {=A3:E3*{1;2;3;4;5}}.

Jadi jika Anda menggunakan Konstanta Vertikal pada ARRAY 1 Dimensi Horizontal (atau sebaliknya), maka Excel hanya akan menggunakan konstanta pertama {1;2;3;4;5} (dalam contoh ini angka 1) untuk perhitungan selanjutnya.

Lalu bagaimana jika Saya ingin menggunakan Konstanta Vertikal dan Horizontal secara bersamaan ? Untuk tujuan tersebut, silahkan perhatikan contoh berikut:

#3 Konstanta ARRAY 2 Dimensi

Penting! Pada SUB-BAB pertama, Saya sudah membahas tentang Dimensi pada Rumus ARRAY. Anda belum tahu ? Silahkan gunakan Pintasan Panduan.

Jika Anda betul-betul memahami aturan penulisan Konstanta vertikal dan horizontal di atas, tentu tidak akan sulit membuat konstanta 2 dimensi ini.

Anda hanya perlu fokus dan teliti menggunakan titik koma (;) dan koma (,) sebagai pemisah antara item vertikal dan horizontal. Note: titik koma (;) dan backslash (\) untuk format Indonesia. Misalnya seperti contoh berikut:

Perhatikan, data tersusun dalam 4 baris dan 4 kolom. Untuk menggunakan konstanta 2 dimensi, Anda harus memulainya dari baris pertama, kemudian lanjutkan ke baris ke 2 dan seterusnya.

Biar semakin paham, silahkan ikuti cara membuat konstanta 2 dimensi berikut:

1. Pilih (blok) range yang akan menggunakan Konstanta Rumus ARRAY (pilih sebanyak data yang akan dimasukkan). Dalam contoh ini, range C₈:F₁₁
2. Ketik tanda sama dengan dan buka kurung kurawal ={
3. Masukkan setiap item konstanta pada baris pertama terlebih dahulu. Dalam contoh ini 16,28,13,17. Dan jangan lupa pisahkan setiap item dengan tanda koma (English) atau titik koma (Indonesia) karena konstanta baris pertama merupakan Konstanta Horizontal.
4. Ketik tanda titik koma (;) untuk memberitahu Excel bahwa konstanta Horizontal baris pertama sudah selesai dan kita akan masuk ke baris berikutnya.
5. Masukkan setiap item konstanta pada baris ke dua yaitu 28,14,27,27.
6. Ketik kembali tanda titik koma (;) dan lanjutkan sisa data Anda dengan cara yang sama.
7. Ketik tanda tutup kurung kurawal } dan tekan Ctrl + Shift + Enter. Lihat hasilnya:

Bagaimana, apakah sejauh ini Anda menemui kesulitan ? Mudah-mudah tidak ya… Jika ada kekeliruan, jangan lupa beritahu Saya pada kolom komentar.

BONUS: Jika Konstanta Berupa Teks

Jika konstanta yang ingin Anda masukkan berupa teks (bukan angka valid), maka silahkan apit setiap item menggunakan kutip 2 " ".

Misalnya pada Range C₇:F₇, silahkan gunakan Konstanta berikut: ={"Data 1","Data 2","Data 3","Data 4"} kemudian tekan Ctrl + Shift + Enter. Hasilnya sama seperti berikut:

Mudah bukan ? Jadi jika item pada konstanta Anda berupa text, jangan lupa apit dengan kutip 2 " ".

Oh ya, Anda tidak bisa menggunakan cell / range / rumus / ARRAY / fungsi sebagai item pada konstanta rumus ARRAY seperti ini: ={"Data 1","Data 2",A3:A4} atau ={270,400,SUM(A3:A4)}. Melain kan hanya untuk angka dan teks saja.

Tapi Anda bisa mengubah reference cell / rumus menjadi konstanta dengan menekan tombol F9 (seperti cara pertama pada Panduan ini).

Next Saya akan membuat beberapa contoh penggunaan Rumus ARRAY yang lebih kompleks untuk berbagai tujuan.