Anda disini: M Jurnal » Rumus Excel » Gabungan Rumus IF + AND, Aturan Penulisan dan Contoh

Gabungan Rumus IF + AND, Aturan Penulisan dan Contoh

Note: Panduan Gabungan Rumus IF AND ini bukan gabungan 2 (atau lebih) Fungsi IF dengan “And” Kriteria. Misalnya seperti hasil pada gambar berikut:

cara menggunakan fungsi if bertingkat "And" Kriteria

Tulis Rumus / Fungsi:
=
IF(B2>=75,IF(C2>=80,“LULUS”,“GAGAL”),“GAGAL”)

Lihat… tidak ada Fungsi AND yang digunakan dalam Rumus tersebut. Melainkan menggabungkan 2 Rumus IF yang mana Rumus IF kedua berada pada argumen value_if_true Rumus IF pertama.

Gabungan 2 (atau lebih) Rumus IF seperti ini disebut juga dengan Rumus IF “And” Kriteria. Materi ini sudah Saya bahas pada SUB-BAB IF Function. (Lihat Pintasan Panduan).

Berbeda dengan Panduan kali ini

Anda akan belajar menggabungkan Fungsi IF dengan Fungsi AND menjadi 1 Rumus. Saya juga melengkapi contoh untuk Rumus IF + AND Tunggal, dan Bertingkat.

Dan tentunya, dengan menggabungkan Rumus IF + AND, Anda bisa melakukan pengujian dengan kriteria yang lebih bervariasi dan rumit.

Ads

Untuk itu, silahkan pahami baik-baik cara menggabungkan Fungsi IF + AND mulai dari aturan penulisannya terlebih dahulu…

Aturan Penulisan dan Makna Gabungan Rumus IF + AND

Penting! Ada perbedaan operator pemisah dalam argumen rumus Excel. Format English menggunakan koma (,), sedangkan Format Indonesia menggunakan titik koma ( ; ). Software Excel Saya menggunakan Format English. Jika Anda ragu, silahkan kunjungi Panduan Format English VS Indonesia.

Pertama-tama coba lihat kembali aturan penulisan Rumus IF berikut:

Aturan Penulisan Rumus IF:
=IF(logical_test,[value_if_true],[value_if_false])

Dan Rumus AND berikut:

Aturan Penulisan Rumus AND:
=AND(logical1,[logical2],)

Ketika menggabungkan Rumus IF dengan AND, Anda bisa memasukkan Rumus AND pada argumen manapun dari Rumus IF (logical_test atau value_if_true atau value_if_false). Dan tentunya penempatan tersebut akan tergantung dengan tujuan Anda.

Namun, dalam praktiknya, Fungsi AND lebih sering digunakan sebagai argumen logical_test dari Fungsi IF. Sehingga struktur setiap argumen dari gabungan IF + AND seperti ini:

Ads

Tulis Gabungan Fungsi / Rumus IF + AND:
=IF(AND(logical1,[logical2],…),[value_if_true],[value_if_false])

Dari gabungan kedua Fungsi ini, ada 2 hal yang harus Anda pahami…

Pahami 2 Alur Pengujian Gabungan Rumus IF + AND

Pertama, pada dasarnya, argumen logical_test dari Fungsi IF hanya bisa diisi dengan 1 kriteria pengujian, misalnya: =IF(B2>74,

Dalam hal ini, argumen logical_test digantikan dengan Fungsi AND.

Sementara itu, Fungsi AND dapat digunakan untuk menguji 2 (atau lebih) kriteria yang saling berhubungan. Ingat!, kriteria yang saling berhubungan. Seperti ini: =IF(AND(Logical1,[logical2],…), ada 3 argumen (bisa ditambah jika perlu).

Penggabungan ini akan memerintahkan Excel untuk melakukan pengujian argumen logical_test berdasarkan hasil dari Rumus AND.

Kedua, secara default, fungsi AND akan memberikan hasil TRUE jika semua kriteria terpenuhi. Dan memberikan hasil FALSE jika salah satu atau semua kriteria tidak terpenuhi.

Naah.. jika menggabungkan Fungsi IF + AND (pada argumen logical_test), maka hasil TRUE dari Fungsi AND akan memberikan hasil value_if_true dari fungsi IF.

Begitu juga dengan hasil FALSE dari Fungsi AND akan memberikan hasil value_if_false dari fungsi IF.

Mudah-mudahan tidak bingung yaa… Biar semakin jelas, coba pelajari terlebih dahulu contoh gabungan Rumus IF Tunggal + AND terlebih dahulu.

Contoh Gabungan Rumus IF + AND Tunggal

Dalam contoh ini, Saya akan menggunakan data “Seleksi Penerimaan Karyawan Baru”.

Contoh gabungan Rumus IF + AND Tunggal Excel

Dalam contoh ini, pelamar dinyatakan lulus test jika memenuhi kedua kriteria berikut:

  • Ijazah Terakhir harus S1 dan
  • Score Test Tertulis minimal 80.

Ingat! Pelamar akan dinyatakan Lulus jika ke 2 kriteria terpenuhi. Jika salah satu kriteria tidak terpenuhi, maka pelamar dinyatakan Gagal. Untuk tujuan tersebut, silahkan ikuti cara menggabungkan Rumus IF dan AND berikut:

Cara menggabungkan Rumus IF + AND Tunggal pada Excel
  1. Pertama, Masukkan Fungsi IF seperti berikut: =IF(
  2. Kedua, Masukkan Fungsi AND sebagai argumen logical_test fungsi IF. Sehingga rumus menjadi seperti berikut: =IF(AND(
  3. Ketiga, Masukkan argumen yang dibutuhkan Fungsi AND. Dalam contoh ini ada 2 kriteria yang berhubungan yaitu = S1 dan minimal 80. Rumus akan menjadi seperti ini: =IF(AND(C4=”S1″,D4>=80
  4. Keempat, Ketik tanda tutup kurung untuk mengakhiri argumen rumus AND. Kemudian ketik operator pemisah rumus ( , atau ; ).
  5. Kelima, Masukkan argumen value_if_true (hasil jika kedua kriteria terpenuhi). Kemudian ketik operator pemisah rumus ( , atau ; ), sehingga rumus menjadi =IF(AND(C4=”S1″,D4>=80),“Lulus”,
  6. Keenam, Masukkan argumen value_if_false (hasil jika salah satu atau semua kriteria tidak terpenuhi). Kemudian ketik tanda tutup kurung untuk mengakhiri Rumus IF. Kemudian tekan Enter dan lihat hasilnya:

Penting! Lakukan AutoFill atau Copy Paste cell E4 ke cell E5 sampai E10 untuk menghitung hasil lainnya.

Contoh gabungan Fungsi IF dan Fungsi AND pada Excel

Lihat, hanya “Dedek” (Cell E5) dan “Bela” (Cell E8) yang dinyatakan lulus karena memenuhi ke dua kriteria pada Rumus AND. Sebenarnya apa alasan Excel memberikan hasil tersebut ?

Biar semakin paham, coba perhatikan…

Pahami Makna dan Alur Pengujian Rumus IF + AND Sebagai Dasar Pemahaman

Lihat kembali rumus yang kita gunakan dan perhatikan alur pengujiannya…

Tulis Gabungan Rumus IF + AND:
=IF(AND(C4=”S1″,D4>=80),“Lulus”,“Gagal”)

Artinya:
Jika Kriteria C4=S1 dan D4>=80 terpenuhi, maka Lulus selain dari itu Gagal

Pertama-tama, Excel mengeksekusi argumen pertama dari Rumus IF (defaultnya adalah logical_test) =IF(logical_test

Berhubung argumen logical_test diisi dengan Rumus AND, maka Excel akan menggunakan kriteria dalam Rumus AND.

Dalam Rumus AND, jika semua kriteria (argumen) terpenuhi, maka akan memberikan hasil TRUE. Jika salah satu atau semua kriteria tidak terpenuhi maka memberikan hasil FALSE.

Nah sampai tahap ini, Excel akan mendapatkan hasil seperti berikut:

NamaIjazah TerakhirTest TertulisHasil Rumus AND
RolanS1 (Terpenuhi)79 (Tdk Terpenuhi)FALSE
DedekS1 (Terpenuhi)82 (Terpenuhi)TRUE
AdeSMA (Tdk Terpenuhi)90 (Terpenuhi)FALSE
PutriSMA (Tdk Terpenuhi)72 (Tdk Terpenuhi)FALSE
BelaS1 (Terpenuhi)87 (Terpenuhi)TRUE
MasayuS2 (Tdk Terpenuhi)89 (Terpenuhi)FALSE
Tabel: Alur Pengujian Gabungan Rumus IF + AND

Selanjutnya, Excel menggunakan hasil rumus AND ini untuk menentukan apakah menggunakan argumen value_if_true atau value_if_false sebagai hasil.

Dari nama argumen nya saja pasti sudah tahu. Jika hasil TRUE, maka menggunakan value_if_true. Jika hasil FALSE maka menggunakan value_if_valse. (Lihat kembali Gambar Hasil Rumus ini).

Mungkin Anda bertanya-tanya, kenapa “Masayu” tidak memenuhi kriteria, padahal memiliki ijazah S2 serta nilai test tertulis > 80.

Kita bahas kriterianya satu per satu…

Pertama, nilai test tertulis 89 dan ini memenuhi kriteria karna lebih besar dari 80. Ini sudah benar.

Kedua, Masayu menggunakan Ijazah S2. Sementara kriterianya adalah Harus Ijazah S1. Selain dari itu, tentu tidak memenuhi kriteria.

Anda juga bisa lihat Operator Perbandingan Rumus untuk kriteria ini =IF(AND(C4=“S1”,D4>=80),. Saya menggunakan tanda =. Jadi jika tidak sama dengan S1, maka tidak memenuhi kriteria.

Penting! ada banyak jenis operator perbandingan rumus seperti =, >, <, dll. Materi ini sudah Saya bahas pada SUB-BAB Comparison Operators (Lihat Pintasan Panduan).

Bagaimana Jika Ada Kriteria Tambahan ?

Tergantung…

Selama kriteria tersebut memiliki hubungan dengan kriteria lainnya, maka Anda bisa memasukkannya ke dalam argumen Fungsi AND.

Misalnya, Saya tambah 1 kriteria lagi yaitu Nilai Test Wawancara harus >=75. Pelamar dinyatakan lulus jika semua kriteria terpenuhi.

Untuk tujuan tersebut, Anda hanya perlu menambahkan kriteria yang baru ke dalam argumen rumus AND seperti berikut =IF(AND(C4=”S1″,D4>=80,E4>=75),”Lulus”,”Gagal”) dan lihat hasilnya:

Logical Test Fungsi IF menggunakan Fungsi AND 3 Kriteria

Benar bukan ? Hanya “Bela” (Cell F8) yang memenuhi semua kriteria.

Kenapa “Dedek” tidak lulus ? Karena nilai Test Wawancara dibawah kriteria yaitu 72 dari minimal 75.

Oh ya, penambahan kriteria baru ke dalam argumen Rumus AND juga memiliki arti tambahan sebagai berikut:

Artinya:
Jika Kriteria C4=S1, D4>=80 dan E4>=75 terpenuhi, maka Lulus selain dari itu Gagal

Begitu seterusnya jika Anda menambahkan kriteria baru yang berhubungan dengan kriteria lainnya.

IF + AND Tunggal VS IF Bertingkat “And” Kriteria

Jika Anda perhatikan, Gabungan Rumus IF + AND Tunggal ini hampir sama dengan IF Bertingkat “And” Kriteria.

Dalam IF Bertingkat “And” Kriteria, kita tidak menggunakan Rumus AND sebagai argumen logical_test, melainkan hanya menggunakan lebih dari 1 rumus IF.

Menggunakan contoh sebelumnya, Anda bisa menggunakan rumus berikut untuk mendapatkan hasil yang sama.

Tulis Rumus IF “And” Kriteria:
=
IF(C4=”S1″,IF(D4>=80,IF(E4>=75,“LULUS”,“GAGAL”),“GAGAL”),“GAGAL”)

Rumus IF AND Tunggal VS IF Bertingkat "And" Kriteria

Note: Gambar Salah edit. Teks IF bertingkat “Or” Kriteria seharusnya IF Bertingkat “And” Kriteria. Maafkan Saya yaa.. hihi.

Benar bukan ?

Namun semakin banyak kriteria yang Anda butuhkan, maka semakin banyak pula Rumus IF yang digunakan.

Dalam contoh ini cuma ada 3 kriteria. Bagaimana jika lebih dari 20 atau 30 kriteria ? Sepanjang apa rumus yang dibuat ? Itu lah sebabnya gabungan Rumus IF + AND jauh lebih cocok dan mudah dipahami.

Jadi cukup gunakan kombinasi yang terbaik dan sesuai tujuan Anda.

Saya punya contoh yang lebih rumit lagi nih…

Contoh Gabungan Rumus IF + AND Bertingkat

Dalam keadaan lain, Anda akan membutuhkan Gabungan Rumus IF + AND BERTINGKAT.

Penting! Contoh ini jauh lebih rumit dari semua contoh Rumus IF sebelumnya. Pastikan Anda sudah memahami SUB-BAB Comparison Operators, IF Function, 3 Kondisi (Lihat Pintasan Panduan) serta Semua Contoh dalam SUB-BAB ini.

Sebagai contoh, Saya menggunakan pertanyaan dari salah satu Member M Jurnal yaitu:

Contoh Soal Menggabungkan Rumus IF Bertingkat + Fungsi AND di Excel

Jadi tujuannya adalah menentukan penamaan dari hasil Pre Test dan Post Test dengan Syarat sesuai Rentang Nilai yang telah ditentukan.

Note: Setelah Saya cek, ternyata beberapa Rentang Nilai untuk kriteria tersebut saling bertumpuk dan menyebabkan hasil yang tidak akurat. Jadi Saya mengubah beberapa kriteria (Pre dan Post Test).

Biar lebih mudah dicerna, Saya menyusun tabulasi kriteria (yang sudah disesuaikan) seperti ini:

Pre TestPost TestPenamaan / Level
0 – 500 – 50Deadwood
> 50 – 1000 – 50Inconsistent
0 – 100> 50 – 75Continuity Player
0 – 75> 75 – 100High Professional
> 75 – 100> 75 – 100Consistency Star
Tabel: Contoh Soal Gabungan Rumus IF + AND Bertingkat

Perhatikan! Kriteria dalam contoh ini berupa Rentang Data (Misal Pre Test untuk Deadwood yaitu jika nilainya dari 0 sampai 50. Begitu juga dengan Post Test untuk Deadwood.

Selain itu, Penamaan / Level ada 5 (Deadwood, Inconsistent dst…). Artinya ada banyak sekali kriteria pada contoh ini.

Untuk contoh ini, Saya buat soal latihan seperti berikut:

Cara Menggabungkan Rumus IF Bertingkat dengan Fungsi AND untuk pengujian logika yang lebih rumit

Ada daftar Nilai Pre dan Post Test dari beberapa peserta. Tujuannya: Kita akan menentukan Penamaan / Level setiap Peserta berdasarkan nilai Pre dan Post Test tersebut.

Biar semakin mudah, tahap-tahap penggabungan rumus IF + AND Bertingkat dalam contoh ini Saya bagi menjadi 3 tahap:

#1 Buat Dan Pahami Pengujian Kriteria Untuk Hasil Pertama

Jadi dalam argumen Rumus AND, buatlah 2 kriteria yang merujuk ke cell yang sama. Kriteria pertama untuk rentang nilai terendah, sedangkan yang kedua untuk rentang tertinggi.

Jadi rumus awal di Cell H4 seperti ini: =IF(AND(F4>=0,F4<=50,

Lihat, kedua kriteria merujuk pada 1 Cell yang sama yaitu F4. Kriteria pertama untuk nilai terendah F4>=0. Sedangkan kriteria kedua untuk nilai tertinggi F4<=50

Note: Kriteria F4>=0 artinya lebih besar dari atau sama dengan 0. Berarti 100 atau 1.000 ataupun 5.000.000 juga termasuk benar. Untuk itu kriteria ke dua akan membatasi dengan F4<=50. Sehingga nilai yang lebih besar dari 0 tidak boleh lebih dari 50.

Itu baru kriteria Pre test untuk Deadwood. Selanjutnya, buat pula 2 buah kriteria untuk Post Test Deadwood.

Kurang lebih rumus menjadi seperti ini: =IF(AND(F4>=0,F4<=50,G4>=0,G4<=50),"Deadwood",

Note: Karena hanya ada 2 pengujian (Pre dan Post Test), maka tutup kurung Rumus AND untuk mengakhirinya. Kemudian lanjutkan isi argumen value_if_true.

Karena kriteria ini untuk penamaan Deadwood, maka ketik “Deadwood” untuk argumen value_if_true.

#2 Buat Pengujian Kriteria Untuk Hasil Ke 2, 3 dst…

Setelah value_if_true, tentu isi argumen value_if_false doong…

Karena menggunakan penamaan yang berbeda, maka disinilah peran Rumus IF Bertingkat “Or” kriteria digunakan.

Jadi masukkan Rumus IF serta AND yang ke 2 menjadi =IF(AND(F4>=0,F4<=50,G4>=0,G4<=50),"Deadwood",IF(AND(

Selanjutnya buat kriteria pada rumus AND untuk penamaan Inconsistent, Continuity Player, High Profesional, dan Consitence Star. Caranya sama saja dengan Tahap Pertama untuk Deadwood.

Jika sudah Selesai, pastikan rumusnya seperti ini:

=IF(AND(F4>=0,F4<=50,G4>=0,G4<=50),"Deadwood",IF(AND(F4>50,F4<=100,G4>=0,G4<=50),"Inconsistent",IF(AND(F4>=0,F4<=100,G4>50,G4<=75),"Continuity Player",IF(AND(F4>=0,F4<=75,G4>75,G4<=100),"High Profesional",IF(AND(F4>75,F4<=100,G4>75,G4<=100),"Consistence Star",

Ingat, di akhir rumus ada operator pemisah rumus (tanda koma , ). Ini untuk melanjutkan ke argumen berikutnya…

#3 Akhiri Rumus Dengan Benar

Karena tidak ada lagi penamaan / level yang diinginkan, maka selesaikan rumus dengan sisa aturan yang ada. Pastikan rumus saat ini diakhiri dengan operator pemisah rumus (, atau ; ). Kemudian Excel akan memberikan petunjuk. Argumen apa yang harus diisi selanjutnya:

Gabungan Rumus IF + AND Bertingkat di Excel

value_if_false bukan ? Yaa… Silahkan isi argumen tersebut.

Anggap saja Anda ingin memberikan pesan kesalahan khusus yang menunjukkan bahwa ada kesalahan dalam data jika SEMUA KRITERI TIDAK TERPENUHI.

Misalnya, Saya menggunakan ini: “Data Salah Oom”

Terakhir, akhiri rumus dengan menutup semua tanda tutup kurung yang belum ditutup. Dalam contoh ini ada 5 tutup kurung dari Fungsi IF yang belum ditutup.

Jadi ketik itu, tekan Enter dan lakukan AutoFill / Copy Paste Rumus ke cell berikutnya:

Gabungan Rumus IF + AND Bertingkat di Excel

Benar bukan ? Silahkan buktikan sendiri setiap nilai Pre dan Post peserta berdasarkan kriteria yang sudah ditentukan.

Saya sudah cek berkali-kali… Rentang Kriteria dan Rumus yang digunakan tidak ada kesalahan. Namun jika Anda menemukan kesalahan, jangan ragu… Sampaikan saja dalam kolom komentar…

Namun 1 yang perlu Saya buktikan, ketika nilai Pre ataupun Post test lebih kecil dari 0 atau lebih besar dari 100 atau bukan berupa angka dari 0 – 100, maka Excel akan memberikan hasil value_if_false dari rumus seperti berikut:

Pembuktian keakuratan Kriteria dari Gabungan Rumus IF + AND Excel

Lihat data pada Cell F4, F9, F12, G7, G11, dan G12 tidak sesuai dengan rentang kriteria manapun.

Bagaimana ? Sejauh ini apa Anda menemukan kesulitan ?

Next kita akan belajar materi yang lebih menarik lagi… Silahkan gunakan Pintasan Panduan berikut:

Pintasan Panduan Logical Function Excel

  1. Logical: Jenis-jenis Fungsi logika (IF, AND, OR, NOT) dan cara menggunakannya (Level dasar).
  2. Comparison Operators: Operator Pembanding untuk Fungsi Logical (seperti sama dengan “=”, lebih besar dari “>”, lebih kecil dari “<“, tidak sama dengan “<>”, dll).
  3. IF Function: Aturan Penulisan Rumus IF, Cara menggunakannya untuk uji logika (bersyarat). Contohnya Jika A1 > 70, maka B2 = “Lulus”. (IF Tunggal, Bertingkat: Gabungan 2 atau lebih Rumus IF dengan “And” + “Or” Kriteria dll).
  4. IF Bertingkat 3 Kondisi (Atau Lebih): Cara menggunakan rumus IF dengan 3 kondisi (kriteria) + Alternatif Penggunaan Terbaik.
  5. Kombinasi IF + AND: (Anda Disini).
  6. OR: Contoh menggunakan Fungsi OR (Lengkap). Gabungan IF + OR, AND + OR, OR + WEEKDAY, dan XOR.
  7. IFs: Hanya bisa digunakan pada Excel versi 2016 atau lebih baru. Kegunaan Fungsi ini sama dengan Fungsi IF Bertumpuk.
  8. Contains Specific Text: Bertujuan untuk memeriksa apakah cell berisi teks tertentu.
  9. SWITCH: Hanya bisa digunakan pada Excel versi 2016 atau lebih baru. Kegunaan fungsi ini hampir menyerupai fungsi IFs.
  10. IF Cell is Blank: Gabungan Fungsi IF + NOT + ISBLANK untuk cek cell kosong atau tidak. Lalu menggunakan Rumus Perkalian dsb.

Apakah Panduan ini Membantu Menyelesaikan Permasalahan Anda ?

Rolan Mardani

Traktir Saya secangkir kopi supaya kuat begadang untuk membuat konten-konten Panduan yang berkualitas dan membantu menyelesaikan permasalahan Anda.

Bantu Orang Lain... Share Panduan ini:

Komentar Paling Lambat di Balas Pukul 23:59 :)